Register to post in forums, or Log in to your existing account
 

Play RetroMUD
Post new topic  Reply to topic     Home » Forums » Finished MUD Scripts Goto page 1, 2, 3  Next
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Tue Mar 23, 2004 4:20 am   

Aardwolf Spellup Script
 
UPDATED 6/4/2007

Started playing again recently and this script was pretty broken, people made changes in the forum just putting the working script here in full, any problems let me know.

Code:

#CLASS {LgSpellup}
#CLASS 0
#CLASS {LgSpellup|User Commands}
#ALIAS lgsConfig {lgs_sp_config}
#ALIAS spc {lgs_sc_configself}
#ALIAS spco {lgs_sc_configother}
#ALIAS spu {#IF (%null(%1)) {lgs_su_doself} {lgs_su_doother %1}}
#CLASS 0
#CLASS {LgSpellup|Global Functions}
#ALIAS lgs_message {#SHOW {@lgs_logo %ansi(bold,cyan) %-1}}
#VAR lgs_version {0.7}
#VAR lgs_spellups {}
#VAR lgs_others {}
#VAR lgs_logo {%ansi(magenta)(%ansi(cyan)LgSpellup v@lgs_version%ansi(magenta))}
#CLASS 0
#CLASS {LgSpellup|Spell Populator}
#ALIAS lgs_sp_config {lgs_sp_on;lgs_spellups = "";lgs_others = "";lgs_message Finding Your Level.;score}
#ALIAS lgs_sp_on {#T+ {LgSpellup|Spell Populator|Triggers}}
#ALIAS lgs_sp_off {#T- {LgSpellup|Spell Populator|Triggers}}
#ALIAS lgs_sp_lvlfound {lgs_message Level Found->%ansi(bold,white)@lgs_sp_curlevel;lgs_sp_findself}
#ALIAS lgs_sp_findself {lgs_sp_selfs = 1;spells 0 @lgs_sp_curlevel spellup}
#ALIAS lgs_sp_findothers {lgs_sp_selfs = 0;spells 0 @lgs_sp_curlevel other}
#ALIAS lgs_sp_addspell {#IF (@lgs_sp_selfs) {#ADDITEM lgs_spellups "%-1"} {#ADDITEM lgs_others "%-1"}}
#ALIAS lgs_sp_finddone {lgs_spellups = %sort(@lgs_spellups);lgs_others = %sort(@lgs_others);lgs_sp_off;lgs_message finished searching for spellup spells. Found %numitems(@lgs_spellups) self spells and %numitems(@lgs_others) other spells}
#VAR lgs_sp_curlevel {95}
#VAR lgs_sp_selfs {0}
#CLASS 0
#CLASS {LgSpellup|Spell Populator|Triggers} {disable}
#TRIGGER {Level: (%d)%s~|} {lgs_sp_curlevel = %1;lgs_sp_lvlfound}
#TRIGGER {^Level:%s%d%s(*)%sMana*} {lgs_sp_addspell %trim(%1)}
#TRIGGER {^%s(*)%sMana*} {lgs_sp_addspell %trim(%1)}
#TRIGGER {~[Enter key for more or 'q' to stop~]} {#SEND %char(13)}
#TRIGGER {To see all the skills/spells} {#IF (@lgs_sp_selfs) {lgs_sp_findothers} {lgs_sp_finddone}}
#CLASS 0
#CLASS {LgSpellup|Spell Configurer}
#ALIAS lgs_sc_configself {lgs_sc_type = 1;lgs_sc_current = @lgs_sc_self;lgs_sc_mainlist = @lgs_spellups;lgs_sc_createlist;lgs_sc_showpick}
#ALIAS lgs_sc_configother {lgs_sc_type = 0;lgs_sc_current = @lgs_sc_others;lgs_sc_mainlist = @lgs_others;lgs_sc_createlist;lgs_sc_showpick}
#ALIAS lgs_sc_createlist {lgs_sc_picklist = "";#FORALL @lgs_sc_mainlist {#IF (%ismember(%i,@lgs_sc_current)) {#ADDITEM lgs_sc_picklist "%concat("*",%i)"} {#ADDITEM lgs_sc_picklist "%i"}}}
#ALIAS lgs_sc_showpick {#IF (@lgs_sc_type) {lgs_sc_self = %pick("p:Make Changes to Self Profile",@lgs_sc_picklist)} {lgs_sc_others = %pick("p:make Changes to Other Profile",@lgs_sc_picklist)}}
#VAR lgs_sc_type {1}
#VAR lgs_sc_current {}
#VAR lgs_sc_mainlist {}
#VAR lgs_sc_self {}
#VAR lgs_sc_others {}
#VAR lgs_sc_picklist {}
#CLASS 0
#CLASS {LgSpellup|Spellup}
#ALIAS lgs_su_doother {lgs_su_self = 0;lgs_su_on;lgs_su_target = %1;lgs_su_misslist = @lgs_sc_others;lgs_su_domisses}
#ALIAS lgs_su_doself {lgs_su_self = 1;lgs_su_on;lgs_su_checkneed}
#ALIAS lgs_su_checkneed {lgs_su_misslist = @lgs_sc_self;aff}
#ALIAS lgs_su_domisses {#FORALL @lgs_su_misslist {#IF (@lgs_su_self) {c '%i'} {c '%i' @lgs_su_target}};lgs_su_misslist = "";#SEND {echo Spellup Checking For Misses}}
#ALIAS lgs_su_checkdone {#IF (%numitems(@lgs_su_misslist) > 0) {lgs_su_domisses} {lgs_su_done}}
#ALIAS lgs_su_done {lgs_su_off;lgs_message Spellup done!}
#ALIAS lgs_su_on {#T+ {LgSpellup|Spellup|Triggers}}
#ALIAS lgs_su_off {#T- {LgSpellup|Spellup|Triggers}}
#VAR lgs_su_misslist {}
#VAR lgs_su_self {1}
#VAR lgs_su_target {lev}
#CLASS 0
#CLASS {LgSpellup|Spellup|Triggers} {disable}
#TRIGGER {Spellup Checking For Misses} {lgs_su_checkdone}
#TRIGGER {You lost your concentration while trying to cast (*).} {#ADDITEM lgs_su_misslist "%1"}
#TRIGGER {You can't concentrate enough.} {lgs_message Spellup Aborted, most likely in combat;lgs_su_done}
#TRIGGER {Use 'saffects' to see a short version of your affects.} {lgs_su_domisses}
#TRIGGER {They aren't here.} {lgs_message Target left or you typoed! Aborting Spellup;lgs_su_done}
#REGEX {^(.*?):.*} {#IF (%ismember(%trim(%1),@lgs_su_misslist)) {#DELITEM lgs_su_misslist %trim(%1)}}
#CLASS 0


Jesse, Linoge on Aardwolf[/code]


Last edited by jessew on Mon Jun 04, 2007 10:58 pm; edited 5 times in total
Reply with quote
Raymond
Newbie


Joined: 06 Jun 2004
Posts: 1
Location: Singapore

PostPosted: Sun Jun 06, 2004 11:10 am   
 
I have used this script and i just have to say its fantastic!
The only thing which i would like to know is how to reduce the string data it populates.

I am wondering if it could be cause by me doing lgsconfig which each time it will do a #additem. ignoring the previous string. maybe build in a command which will #delitem to the sting before adding new spells
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Tue Jun 08, 2004 5:06 pm   
 
Thanks :) Yep that's what it was , I forgot to clear the variables that hold your list of spells each time you configured it. Just a small change but I added to my previous post, It's highlighted in Red if you just want that line.


Cheers, Jesse
Reply with quote
falconhand
Beginner


Joined: 16 Aug 2004
Posts: 21

PostPosted: Wed Jun 01, 2005 8:21 pm   can't get it to work
 
I tried copying and pasting the text you put for the script in to zMUD and only parts of it were accepted. is there a better way to do this? also an array probebly would be the best idea I have lots of morts and therefore i have over 60 spells on myself. not sure if your still at all interested in this but if so any responce would be great. thank you :)
Reply with quote
falconhand
Beginner


Joined: 16 Aug 2004
Posts: 21

PostPosted: Wed Jun 01, 2005 8:40 pm   
 
ok well i got it working had to paste one pice at at time but now it does the score part finds my lvl and then borks when its goign through the spells because it wants an "enter" hit so that it will go through the list of spells but something else ends up getting hit so it only goes through the first 20 spells.
Reply with quote
nexela
Wizard


Joined: 15 Jan 2002
Posts: 1644
Location: USA

PostPosted: Thu Jun 02, 2005 12:07 am   
 
To paste the whole script in you have to remove all the blank lines first, Maybe Jessew will do this and save us all a bunch of heartache :p
_________________
Zmud Support Library
Zmud Knowledge Base
Reply with quote
falconhand
Beginner


Joined: 16 Aug 2004
Posts: 21

PostPosted: Thu Jun 02, 2005 2:22 am   
 
figured that part out eventualy. so i have a question now, how does this script know which spells are enhancment spells and which ones are offensive and which ones are removal and stuff?
Reply with quote
HawkeyeX
Beginner


Joined: 02 Mar 2005
Posts: 20

PostPosted: Thu Jun 09, 2005 8:32 pm   
 
Nice, except when I hit sc (score) I get bugged out and it keeps adding spells repeatedly.
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Mon Jun 13, 2005 8:03 pm   
 
1. Forgot to mention this sorry, its not a good idea to paste my scripts in. They were meant to be put in a text document, and read into zmud using #READ command (NOT IMPORTED FROM THE MENU)

2. It can discern between the different types of spells because I've perfected AI! ok, I lie aardwolf has a built in command to do this, to find your spellup spells, type spells spellup :)

3. Hawkeye, when my script requests your score, it first turns on a class of triggers that collect this information and then disables those triggers. This works for me. Yours arent being disabled for some reason. The only thing I can suggest is that my script isnt installed correctly you can try deleting the class and installing it like I suggest in 1.

Cheers, Jesse
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
Kylu
Newbie


Joined: 11 Jun 2005
Posts: 9

PostPosted: Fri Jun 17, 2005 4:44 am   
 
Okay.. I'm really new with scripts and all that... would you mind giving a somewhat step-by-step installation guide? Or tell me where I can find one?

If you don't have the time to, it's coo... just asking Smile
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Fri Jun 17, 2005 2:42 pm   
 
The easiest way is to cut and paste my script into notepad or soemthing similar, and save it in your root zmud directory. Then open Aardmud in zmud then (Lets say you called the file spellup.txt) type #read spellup.txt in the command bar.

note:
If you don't save it in the root zmud folder then you will have to type in the full path of where you put it, e.g. #read "c:\program files\spellup.txt"

Cheers, Jesse
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
Kylu
Newbie


Joined: 11 Jun 2005
Posts: 9

PostPosted: Fri Jun 17, 2005 9:49 pm   
 
Wow Jessew... works like a charm! I love it!

Thanks!

--Sam
Reply with quote
Orang
Apprentice


Joined: 22 Jul 2004
Posts: 118
Location: USA

PostPosted: Wed Jul 20, 2005 1:14 pm   
 
awesome script! works great


Last edited by Orang on Tue Sep 06, 2005 7:16 pm; edited 1 time in total
Reply with quote
mandoris
Newbie


Joined: 03 Sep 2005
Posts: 2

PostPosted: Sat Sep 03, 2005 12:04 pm   
 
Thanks for a great script, best one I've found.
Reply with quote
Ithilion
Wanderer


Joined: 02 Sep 2005
Posts: 85

PostPosted: Sun Sep 04, 2005 9:16 am   
 
Um, looks great, but this wont work for me. Im using Zmud 7.13..

do config - do spc, fine
do spu
return -

lgs_su_doself
That is not a command. Type 'Commands' for a complete list.

??? i had no affects on..
Reply with quote
Ithilion
Wanderer


Joined: 02 Sep 2005
Posts: 85

PostPosted: Sat Sep 10, 2005 3:12 pm   
 
o m g i dunno why it took me this long to notice, but the frickin class was disabled n_n
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Sun Sep 11, 2005 2:26 am   
 
Well missed your last post where you got it workign, cant find a delete post button so I'll just write this :p
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
Ithilion
Wanderer


Joined: 02 Sep 2005
Posts: 85

PostPosted: Tue Sep 13, 2005 1:44 pm   
 
Hey i do have one small request? do clanskill section so we dont have to? :D not a big deal, but im sure some would like, so..
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Wed Sep 21, 2005 1:32 am   
 
I could, but one problem, I've never been in a clan and have absolutely no idea how they work. If you want to supply me with the information , pretty sure I can. I would need to know how to list your clanskills, and what the list looks like to be able to do it.

Jesse
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
mandoris
Newbie


Joined: 03 Sep 2005
Posts: 2

PostPosted: Fri Sep 30, 2005 6:03 pm   
 
Don't suppose you can update this script for all the changes Aardwolf recently implemented to the spell timings? I love your script but like many it doesn't work now. :)
Reply with quote
falconhand
Beginner


Joined: 16 Aug 2004
Posts: 21

PostPosted: Fri Sep 30, 2005 7:41 pm   silly updates on Aardwolf
 
Yes! I second that could you please update this for the new updates to Aardwolf.
once i join a clan i will provide you with any info you need about the clanskills :)
probebly not for a year since this is my senior year and im a bit bogged down but eventualy :)
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Fri Sep 30, 2005 8:58 pm   
 
Ok all done, tested it out it seems to work fine, anything I missed let me know.
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
falconhand
Beginner


Joined: 16 Aug 2004
Posts: 21

PostPosted: Sat Oct 01, 2005 6:02 am   
 
I am still having troubles having it auto spell me up when i put in a af or aff.
I read in the file #rea spellup.txt
lgconfig works
spc works
spco works
spu works
but the auto spellup from a/af/aff does not work.
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Sat Oct 01, 2005 1:48 pm   
 
It shouldnt spell you up if you type aff, when you type spu it checks aff to see which spells you dont have that are in your spellup list and recasts only those. Which is pretty much the same thing.

Unless you mean its still trying to recast everything when you type spu? although this is working for me now with changes to the aff trigger.

Jesse
_________________
I love deadlines. I like the whooshing sound they make as they fly by.
Reply with quote
apgar
Newbie


Joined: 01 Oct 2005
Posts: 1

PostPosted: Sat Oct 01, 2005 2:07 pm   
 
Hi

When I install the script and run lgsconfig it finds 53 self spells and 31 other spells.

However when I spc all it shows is %{i}

Any ideas?
Reply with quote
Display posts from previous:   
Post new topic   Reply to topic     Home » Forums » Finished MUD Scripts All times are GMT
Goto page 1, 2, 3  Next
Page 1 of 3

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

© 2009 Zugg Software. Hosted by Wolfpaw.net