Zugg Software :: View topic

Newbie Joined: 24 Jan 2005 Posts: 2

Hello, I need some help with a channel capture script for Achaea. The only problem is that I'm completely clueless when it comes to programing. I searched for some scripts but most of them I found I couldn't get to work properly. They would put all the text into the new window instead of just the channel stuff. After a bit more searching I found one - (thanks to discordia for writting it)

#CLASS {chat}
#CLASS 0
#CLASS {chat|chattrig}
#TRIGGER {^~(*~)~:*} {
#MAKEWINDOW chat "scrolling=yes|align=top|tight=chat"
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend = %char( 34)) {
#CAPTURE chat
#GAG
} {
#T+ chattext
#T- chattrig
}
}
#TRIGGER {^~<~<*~>~>~:*} {
#MAKEWINDOW chat "scrolling=yes|align=top|tight=chat"
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend = %char( 34)) {
#CAPTURE chat
#GAG
} {
#CAPTURE chat
#GAG
#T+ chattext
#T- chattrig
}
}
#CLASS 0
#CLASS {chat|chattext}
#TRIGGER {*} {
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend <> %char( 34)) {
#CAPTURE chat
#GAG
} {
#CAPTURE chat
#GAG
#T+ chattrig
#T- chattext
}
}
#CLASS 0

and it works for me but I would like it to open each channel in a new window and not display the extra prompts in the main window. If any one has any extra time and can help me with this I would appreciate it. Thanks.

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

#CLASS {chat}
#CLASS 0
#CLASS {chat|chattrig}
#TRIGGER {^~((*)~)~:*} {
#VAR channel {%word( %1, 1)}
#MAKEWINDOW {@channel} "scrolling=yes|align=top|title=%1"
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend = %char( 34)) {
#CAPTURE @channel
#GAG
} {
#T+ chattext
#T- chattrig
}
}
#TRIGGER {^~<~<(*)~>~>~:*} {
#VAR channel {%word( %1, 1)}
#MAKEWINDOW {@channel} "scrolling=yes|align=top|title=%1"
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend = %char( 34)) {
#CAPTURE @channel
#GAG
} {
#T+ chattext
#T- chattrig
}
}
#CLASS 0
#CLASS {chat|chattext} disable
#TRIGGER {*} {
#VARIABLE lineend {%rightback( %trigger, 1)}
#IF (@lineend <> %char( 34)) {
#CAPTURE @channel
#GAG
} {
#CAPTURE @channel
#GAG
#T+ chattrig
#T- chattext
}
}
#CLASS 0

I didn't test this on Achaea but it works in off-line tests.

Newbie Joined: 24 Jan 2005 Posts: 2

Thank you VERY much! It works great.