Register to post in forums, or Log in to your existing account
 

Play RetroMUD
Post new topic  Reply to topic     Home » Forums » Finished MUD Scripts
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Sun Dec 14, 2003 9:43 pm   

Medievia - Cool Spellup Script
 
This is my spellup script for Medievia

It is based on Carabas' awesome spellup script.
It allows you to have different spellup profiles
maybe one for each of your characters or one
for lairing etc.
It also pauses when engaged, you entered a no magic room etc

Commands:
spr - Sometimes your spellup will be paused as mentioned
above. If you dont want to finish it, and would like
to run a new profile type this to reset zspellup

spc - Takes you to the menu system.
Managing your profiles are run through a menu system
You can create, delete, modify, rename, set default
or even execute a profile all from the menu system.

sp - This command runs your default profile or a profile that
you name(sp <name of profile) unless your current spellup
is paused, in which case it resumes that profile.

The first profile you create is set to default
automatically by zspellup you can change this through
the menu system later.

I've tested it all this morning and everything seems to be working
fine. But of course there's probably a bug hidden somewhere [}:)][}:)][}:)] so if you have a problem let me know Very Happy

Code:

#CLASS {ZSpellup}
#CLASS 0

#CLASS {ZSpellup|UserCommands}

    #ALIAS spc {zspOptionMenu}
    #ALIAS sp  {#IF (@zspRPaused) {zspRResume} {#IF (%null(%1)) {zspRRunProfName = @zspPDefault;zspRProfToRun = %eval(@@zspPDefault);zspRStart} {#IF (%ismember(%1,@zspProfiles)) {zspRRunProfName = %eval(%1);zspRProfToRun = %eval(@%1);zspRStart} {zspMNSP %1}}}}
    #ALIAS spr {zspRPaused = 0;zspMSRT}
   
#CLASS 0

#CLASS {ZSpellup|PickList Creator}
    #VARIABLE zspPickList {""} {""}
    #VARIABLE zspFullList {"armor|bless|breathe water|detect evil|detect good|detect invisibility|detect magic|fireshield|infravision|invisibility|levitate|manashield|phantasmal image|protection|quickness|sanctuary|sense life|shield|stone skin|strength"}

   
    #ALIAS zspCreateList {zspPickList = ""
                          #FORALL @zspFullList {#IF (%ismember(%i, %eval(@%1))) {
                                                zspPickList = %additem(%concat(*,%i),@zspPickList) } {
                                                zspPickList = %additem(%i,@zspPickList)
                                                }}}
#CLASS 0

#CLASS {ZSpellup|Profiles}

     #VARIABLE zspPDefault {""}
     #VARIABLE zspProfiles {""}
     #VARIABLE zspPTemp    {""}
     #VARIABLE zspPTmpProf {""}
     #VARIABLE zspPTmpName {""}
     
     #ALIAS zspCheckProfile     {#IF (%null(%1)) {zspConfigureProfile @zspPDefault} {#IF (%ismember(%1,@zspProfiles)) {zspConfigureProfile %1} {zspCreateNewProfile %1}}}
     #ALIAS zspCreateNewProfile {zspConfigureProfile %1;#CLASS {ZSpellup|Profiles};#IF (%null(@%1)) {zspMessage zspMNFA} {#IF (%null(@zspPDefault)) {zspPDefault = %1;zspMADF %1};zspProfiles = %additem(%1, @zspProfiles);zspMNFS %1;#CLASS 0}}
     #ALIAS zspConfigureProfile {zspCreateList %1;#CLASS {ZSpellup|Profiles};#VARIABLE {%1} {%pick(@zspPickList)};#CLASS 0}
     #ALIAS zspCDefaultProfile  {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose default profile","o:1",%replaceitem(%concat(*,@zspPDefault),%ismember(@zspPDefault,@zspProfiles),@zspProfiles));#IF (%null(@zspPTemp) || (@zspPTemp = @zspPDefault)) {zspMDNC} {zspPDefault = @zspPTemp;zspMDCS %1}}}
     #ALIAS zspCModifyProfile   {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to Modify","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAMP} {zspCreateList @zspPTemp;zspPTmpProf = %pick("p:Make changes to profile",@zspPickList);#IF (%null(@zspPTmpProf)) {zspMPNM} {#VARIABLE @zspPTemp {@zspPTmpProf};zspMPMS}}}}
     #ALIAS zspCRenameProfile   {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to rename","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMARP} {zspPTmpName = "";zspPTmpName = %prompt("","Enter New Name For Profile");#IF (%null(@zspPTmpName)) {zspMarp} {#CLASS {ZSpellup|Profiles};#VARIABLE {@zspPTmpName} {%eval(@@zspPTemp)};zspProfiles = %delitem(@zspPTemp,@zspProfiles);zspProfiles = %additem(@zspPTmpName,@zspProfiles);#UNVAR {@zspPTemp};#IF (@zspPDefault == @zspPTemp) {zspPDefault = @zspPTmpName};zspMRPS @zspPTemp @zspPTmpName}}}}
     #ALIAS zspcRunAProfile     {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to run","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAEP} {sp @zspPTemp}}}
#CLASS 0

#CLASS {ZSpellup|Configuration Manager}

    #VARIABLE zspCTemp {""} {""}
    #VARIABLE zspConfigList {"Create New Profile"|"Modify Existing Profile"|"Choose New Default Profile"|"Delete A Profile"|"Rename A Profile"|"Run A Profile"}
   
    #ALIAS zspOptionMenu {#CASE %ismember(%pick("p:ZSpellup Menu","o:1",@zspConfigList),@zspConfigList) {zspCNewProfile} {zspCModifyProfile} {zspCDefaultProfile} {zspCDeleteProfile} {zspCRenameProfile} {zspCRunAProfile}}
    #ALIAS zspCNewProfile {zspCTemp = %prompt("", "Enter Name for New Profile");#IF %null(@zspCTemp) {zspMADF %1} {#IF (%ismember(@zspCTemp,@zspProfiles)) {zspMPNE} {zspCreateNewProfile @zspCTemp}}}

#CLASS 0

#CLASS {ZSpellup|Messages}

    #VARIABLE zspLogo     {%ansi(bold,blue)(%ansi(bold,white)ZSpellup V2.0%ansi(bold,blue))}
   
    #ALIAS zspMsg      {#SHOW @zspLogo %ansi(bold,green)%-1}
    #ALIAS zspErrMsg   {#SHOW @zspLogo %ansi(bold,red)Error: %ansi(bold,green) %-1}
   
    #ALIAS zspMAEP  {zspMsg Aborted Running A Profile.}
    #ALIAS zspMSRT  {zspMsg Spellup has been reset.}
    #ALIAS zspMNSP  {zspErrMsg No such profile %ansi(bold,white)%1%ansi(bold,green).}
    #ALIAS zspMRPS  {zspMsg Profile %ansi(bold,white)%1 %ansi(bold,green)renamed to %ansi(bold,white)%2}
    #ALIAS zspMARP  {zspMsg Aborted Profile Rename}
    #ALIAS zspMPMS  {zspMsg Profile %ansi(bold,white)@zspPTemp%ansi(bold,green) modified successfully.}
    #ALIAS zspMPNM  {zspMsg Profile not modified}
    #ALIAS zspMAMP  {zspMsg Aborted Modifying Profile}
    #ALIAS zspMDNC  {zspMsg Default profile not changed from %ansi(bold,white)@zspPDefault}
    #ALIAS zspMDCS  {zspMsg Default profile now is %ansi(bold,white)@zspPDefault}
    #ALIAS zspMNPR  {zspErrMsg You have no profiles, you can create one through the option menu.}
    #ALIAS zspMNFA  {zspMsg Create New File Aborted}
    #ALIAS zspMPNE  {zspErrMsg Profile With That Name Already Exists}
    #ALIAS zspMADF  {zspMsg %ansi(bold,white)%1 %ansi(bold,green)Set to default profile automatically. You can change this through ZSpellup Option Menu}
    #ALIAS zspMNFS  {zspMsg New Profile %ansi(bold,white)%1 %ansi(bold,green)created successfully.}

#CLASS 0

#CLASS {ZSpellup|Spellup}
   
    #VARIABLE zspRProfToRun    {""} {""}
    #VARIABLE zspRRunProfName  {""} {""}
    #VARIABLE zspRPaused    {0}  {0}
    #VARIABLE zspRCurSpell  {0}  {0}
   
    #ALIAS zspRStart  {#T+ {ZSpellup|Spellup|Triggers};zspRCurSpell = 1;zspRMStart;zspRCastSameSpellStart}
    #ALIAS zspRResume {#T+ {ZSpellup|Spellup|Triggers};zspRPaused = 0;zspRMResume;zspRCastSameSpellStart}
    #ALIAS zspRCastNextSpellError   {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMErrorCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
    #ALIAS zspRCastNextSpellSuccess {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMSuccessCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
    #ALIAS zspRCastSameSpellFailure {zspRMCastSame;cast %item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRCastSameSpellStart   {zspRMCastSameStart;cast %item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRSpellupFinished      {#T- {ZSpellup|Spellup|Triggers};zspRMSpellupFinished}
    #ALIAS zspRStandCast            {zspRMStand;stand;zspRCastSameSpellStart}
   
    #ALIAS zspRMStart           {zspMsg Executing Spellup using profile: %ansi(bold,white)@zspRRunProfName}
    #ALIAS zspRMResume          {zspMsg Resuming Spellup using profile: %ansi(bold,white)@zspRRunProfName}
    #ALIAS zspRMCastSame        {zspMsg %ansi(bold,red)Failure %ansi(bold,green)Recasting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMCastSameStart   {zspMsg Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMErrorCastNext   {zspMsg %ansi(bold,red)Failure %ansi(bold,green)skipping %ansi(bold,white)%item(@zspRProfToRun,%eval(@zspRCurSpell-1)) %ansi(bold,green)Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMSuccessCastNext {zspMsg %ansi(bold,cyan)Success %ansi(bold,green)now casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMPausing         {#T- {ZSpellup|Spellup|Triggers};zspMsg %ansi(bold,yellow)Pausing Spellup %ansi(bold,green)%-1;zspRPaused = 1}
    #ALIAS zspRMStand           {zspMsg %ansi(bold,yellow)Auto-Standing and resuming.}
    #ALIAS zspRMSpellupFinished {zspMsg %ansi(bold,blue)Spellup %ansi(bold,yellow)@zspRRunProfName %ansi(bold,yellow)Finished Successfully.}

#CLASS 0

#CLASS {ZSpellup|Spellup|Triggers} {disable}
    #TRIGGER {Sorry, you can't do that.} {zspRCastNextSpellError}
    #TRIGGER {You have not practiced that spell!} {zspRCastNextSpellError}
   
    #TRIGGER {Sparkles of light fill the area, as the magic is absorbed into the surroundings.} {zspRMPausing No Magic Room, please leave and resume spellup}
    #TRIGGER {The battle distracts you from your spell casting.} {zspRMPausing You are in combat please resume spellup when finished.}
    #TRIGGER {You can't summon enough energy to cast the spell.} {zspRMPausing Not Enough Mana Pausing, tick and resume spellup.}
    #TRIGGER {You dream of accomplishing such great and wonderous feats.} {zspRMPausing Your sleeping please wake up and resume spellup.}
   
    #TRIGGER {That is impossible to do while sitting.} {zspRStandCast}
    #TRIGGER {You have to stand up before you can do that.} {zspRStandCast}

    #TRIGGER {You chant out the arcane words and are drained of %d mana.} {zspRCastNextSpellSuccess}
    #TRIGGER {You fumble over the correct inflection *}  {zspRCastSameSpellFailure}
#CLASS 0

#T- {ZSpellup|Spellup|Triggers}


btw, if you happened to use my first version of this without the profiles you need to delete that ZSpellup class before reading in
this one.

Cheers Caebryn
Reply with quote
Carabas
GURU


Joined: 28 Sep 2000
Posts: 434
Location: USA

PostPosted: Wed Dec 17, 2003 6:10 am   
 
Very nice. I always wanted to add profiles to my script, but never had the time.

Pausing the script, rather than having to reset it and start over was also a nice touch.

I may tweak this to my own liking, if I have the time. If you wish I will send you any changes I make.

Let me know.
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Wed Dec 17, 2003 12:01 pm   
 
Wow, what an awesome script, I love it.

Only thing I notice right away is that map catacombs is not in the list. That would be nice to add to combs spellup.

Lovin it
Tlaca
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Wed Dec 17, 2003 1:24 pm   
 
I've been playing with some stuff :)

I discovered how to add map catacombs to the list, a very user friendly
script I must say [8D]

One thing I'd like to add is something I got with one of carabas's scripts
off of clangersidi. It gave a status command to count the seconds that
my sanc was going to be active for. So far, the best I can come up with
is a trigger that when I type affects, it assigns the number of ticks to
a variable that I then display in the status bar. So it doesn't stay current.

I'm pretty sure it was in his spellup script, but when i downloaded it just now,
it didn't do that. This would be a cool addition.

I'd be happy with it putting the current ticks, rather than irl seconds.
But I don't know how to get or assign that information without displaying
affects and triggering it.

Tlaca
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Wed Dec 17, 2003 5:26 pm   
 
There was a few problems with the menu system, like missing the ability to delete a profile and a few other, there all fixed now

I also added command 'spp' so you can manually pause your spellup.

And map catacombs is in here.

Im also trying to find the best way of adding multiple strengths to
spellup list, Im thinking that when you hit strength a new window
will come up and ask how many you want to cast, gotta fool around with it.
Code:


#DELCLASS {ZSpellup}

#CLASS {ZSpellup}
#CLASS 0

#CLASS {ZSpellup|UserCommands}

    #ALIAS spc {zspOptionMenu}
    #ALIAS sp  {#IF (@zspRPaused) {zspRResume} {#IF (%null(%1)) {#IF (!%null(@zspPDefault)) {zspRRunProfName = @zspPDefault;zspRProfToRun = %eval(@@zspPDefault);zspRStart} {zspMNDP}} {#IF (%ismember(%1,@zspProfiles)) {zspRRunProfName = %eval(%1);zspRProfToRun = %eval(@%1);zspRStart} {zspMNSP %1}}}}
    #ALIAS spr {zspRBRunning = 0;zspRPaused = 0;zspMSRT}
    #ALIAS spp {#IF (@zspRPaused) {zspMAPS} {#IF (@zspRBRunning) {zspRPaused = 1;zspRMPausing;#T- {ZSpellup|Spellup|Triggers}} {zspMNBR}}}
   
#CLASS 0

#CLASS {ZSpellup|PickList Creator}
    #VARIABLE zspPickList {""} {""}
    #VARIABLE zspFullList {"armor|bless|breathe water|detect evil|detect good|detect invisibility|detect magic|fireshield|infravision|invisibility|levitate|manashield|map catacombs|phantasmal image|protection|quickness|sanctuary|sense life|shield|stone skin|strength"}

   
    #ALIAS zspCreateList {zspPickList = ""
                          #FORALL @zspFullList {#IF (%ismember(%i, %eval(@%1))) {
                                                zspPickList = %additem(%concat(*,%i),@zspPickList) } {
                                                zspPickList = %additem(%i,@zspPickList)
                                                }}}
#CLASS 0

#CLASS {ZSpellup|Profiles}

     #VARIABLE zspPDefault {""}
     #VARIABLE zspProfiles {""}
     #VARIABLE zspPTemp    {""}
     #VARIABLE zspPTmpProf {""}
     #VARIABLE zspPTmpName {""}
     
     #ALIAS zspCheckProfile     {#IF (%null(%1)) {zspConfigureProfile @zspPDefault} {#IF (%ismember(%1,@zspProfiles)) {zspConfigureProfile %1} {zspCreateNewProfile %1}}}
     #ALIAS zspCreateNewProfile {zspConfigureProfile %1;#CLASS {ZSpellup|Profiles};#IF (%null(%eval(@%1))) {zspMNFA;#UNVAR {%1}} {#IF (%null(@zspPDefault)) {zspPDefault = %1;zspMADF %1};zspProfiles = %additem(%1, @zspProfiles);zspMNFS %1;#CLASS 0}}
     #ALIAS zspConfigureProfile {zspCreateList %1;#CLASS {ZSpellup|Profiles};#VARIABLE {%1} {%pick(@zspPickList)};#CLASS 0}
     #ALIAS zspCDefaultProfile  {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose default profile","o:1",%if(%null(@zspPDefault),@zspProfiles,%replaceitem(%concat(*,@zspPDefault),%ismember(@zspPDefault,@zspProfiles),@zspProfiles)));#IF (%null(@zspPTemp) || (@zspPTemp = @zspPDefault)) {zspMDNC} {zspPDefault = @zspPTemp;zspMDCS %1}}}
     #ALIAS zspCModifyProfile   {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to Modify","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAMP} {zspCreateList @zspPTemp;zspPTmpProf = %pick("p:Make changes to profile",@zspPickList);#IF (%null(@zspPTmpProf)) {zspMPNM} {#VARIABLE @zspPTemp {@zspPTmpProf};zspMPMS}}}}
     #ALIAS zspCRenameProfile   {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to rename","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMARP} {zspPTmpName = "";zspPTmpName = %prompt("","Enter New Name For Profile");#IF (%null(@zspPTmpName)) {zspMarp} {#CLASS {ZSpellup|Profiles};#VARIABLE {@zspPTmpName} {%eval(@@zspPTemp)};zspProfiles = %delitem(@zspPTemp,@zspProfiles);zspProfiles = %additem(@zspPTmpName,@zspProfiles);#UNVAR {@zspPTemp};#IF (@zspPDefault == @zspPTemp) {zspPDefault = @zspPTmpName};zspMRPS @zspPTemp @zspPTmpName}}}}
     #ALIAS zspCRunAProfile     {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to run","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAEP} {sp @zspPTemp}}}
     #ALIAS zspCDeleteProfile   {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to delete","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMADP} {#CLASS {ZSpellup|Profiles};#UNVAR {%eval(@zspPTemp)};zspProfiles = %delitem(@zspPTemp,@zspProfiles);#CLASS 0;zspMDPS @zspPTemp;#IF (@zspPDefault == @zspPTemp) {#IF (%null(@zspProfiles)) {zspPDefault = "";zspMDNP} {zspMDDP;zspPDefault = "";zspCDefaultProfile}}}}}
#CLASS 0

#CLASS {ZSpellup|Configuration Manager}

    #VARIABLE zspCTemp {""} {""}
    #VARIABLE zspConfigList {"Create New Profile"|"Modify Existing Profile"|"Choose New Default Profile"|"Delete A Profile"|"Rename A Profile"|"Run A Profile"}
   
    #ALIAS zspOptionMenu {zspCTemp = %ismember(%pick("p:ZSpellup Menu","o:1",@zspConfigList),@zspConfigList);#IF (@zspCTemp) {#CASE @zspCTemp {zspCNewProfile} {zspCModifyProfile} {zspCDefaultProfile} {zspCDeleteProfile} {zspCRenameProfile} {zspCRunAProfile}}}
    #ALIAS zspCNewProfile {zspCTemp = %prompt("", "Enter Name for New Profile");#IF %null(@zspCTemp) {zspMADF %1} {#IF (%ismember(@zspCTemp,@zspProfiles)) {zspMPNE} {zspCreateNewProfile @zspCTemp}}}

#CLASS 0

#CLASS {ZSpellup|Messages}

    #VARIABLE zspLogo     {%ansi(bold,blue)(%ansi(bold,white)ZSpellup V2.0%ansi(bold,blue))}
   
    #ALIAS zspMsg      {#SHOW @zspLogo %ansi(bold,green)%-1}
    #ALIAS zspErrMsg   {#SHOW @zspLogo %ansi(bold,red)Error: %ansi(bold,green) %-1}
   
    #ALIAS zspMNBR  {zspErrMsg You are not running a profile now.}
    #ALIAS zspMAPS  {zspErrMsg Spellup is already paused, use %ansi(bold,white)sp to resume}
    #ALIAS zspMNDP  {zspErrMsg You have not set a default profile, please use menu system to select one.}
    #ALIAS zspMDPS  {zspMsg Successfuly deleted %ansi(bold,white)%1 %ansi(bold,green)profile.}
    #ALIAS zspMDNP  {zspMsg You have no profiles, please create a new one.}
    #ALIAS zspMDDP  {zspMsg You have deleted your default profile, please select a new one.}
    #ALIAS zspMADP  {zspMsg Aborted Profile Delete.}
    #ALIAS zspMAEP  {zspMsg Aborted Running A Profile.}
    #ALIAS zspMSRT  {zspMsg Spellup has been reset.}
    #ALIAS zspMNSP  {zspErrMsg No such profile %ansi(bold,white)%1%ansi(bold,green).}
    #ALIAS zspMRPS  {zspMsg Profile %ansi(bold,white)%1 %ansi(bold,green)renamed to %ansi(bold,white)%2}
    #ALIAS zspMARP  {zspMsg Aborted Profile Rename}
    #ALIAS zspMPMS  {zspMsg Profile %ansi(bold,white)@zspPTemp%ansi(bold,green) modified successfully.}
    #ALIAS zspMPNM  {zspMsg Profile not modified}
    #ALIAS zspMAMP  {zspMsg Aborted Modifying Profile}
    #ALIAS zspMDNC  {zspMsg Default profile not changed from %ansi(bold,white)@zspPDefault}
    #ALIAS zspMDCS  {zspMsg Default profile now is %ansi(bold,white)@zspPDefault}
    #ALIAS zspMNPR  {zspErrMsg You have no profiles, you can create one through the option menu.}
    #ALIAS zspMNFA  {zspMsg Create New Profile Aborted}
    #ALIAS zspMPNE  {zspErrMsg Profile With That Name Already Exists}
    #ALIAS zspMADF  {zspMsg %ansi(bold,white)%1 %ansi(bold,green)Set to default profile automatically. You can change this through ZSpellup Option Menu}
    #ALIAS zspMNFS  {zspMsg New Profile %ansi(bold,white)%1 %ansi(bold,green)created successfully.}

#CLASS 0

#CLASS {ZSpellup|Spellup}
   
    #VARIABLE zspRProfToRun    {""} {""}
    #VARIABLE zspRRunProfName  {""} {""}
    #VARIABLE zspRPaused    {0}  {0}
    #VARIABLE zspRCurSpell  {0}  {0}
    #VARIABLE zspRBRunning  {0}  {0}
   
    #ALIAS zspRStart  {zspRBRunning = 1;#T+ {ZSpellup|Spellup|Triggers};zspRCurSpell = 1;zspRMStart;zspRCastSameSpellStart}
    #ALIAS zspRResume {#T+ {ZSpellup|Spellup|Triggers};zspRPaused = 0;zspRMResume;zspRCastSameSpellStart}
    #ALIAS zspRCastNextSpellError   {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMErrorCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
    #ALIAS zspRCastNextSpellSuccess {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMSuccessCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
    #ALIAS zspRCastSameSpellFailure {zspRMCastSame;cast %item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRCastSameSpellStart   {zspRMCastSameStart;cast %item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRSpellupFinished      {#T- {ZSpellup|Spellup|Triggers};zspRMSpellupFinished}
    #ALIAS zspRStandCast            {zspRMStand;stand;zspRCastSameSpellStart}
    #ALIAS zspRPausing              {#T- {ZSpellup|Spellup|Triggers};zspRMPausing}
   
    #ALIAS zspRMStart           {zspMsg Executing Spellup using profile: %ansi(bold,white)@zspRRunProfName}
    #ALIAS zspRMResume          {zspMsg Resuming Spellup using profile: %ansi(bold,white)@zspRRunProfName}
    #ALIAS zspRMCastSame        {zspMsg %ansi(bold,red)Failure %ansi(bold,green)Recasting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMCastSameStart   {zspMsg Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMErrorCastNext   {zspMsg %ansi(bold,red)Failure %ansi(bold,green)skipping %ansi(bold,white)%item(@zspRProfToRun,%eval(@zspRCurSpell-1)) %ansi(bold,green)Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMSuccessCastNext {zspMsg %ansi(bold,cyan)Success %ansi(bold,green)now casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
    #ALIAS zspRMPausing         {zspMsg %ansi(bold,yellow)Pausing Spellup %ansi(bold,green)%-1;zspRPaused = 1}
    #ALIAS zspRMStand           {zspMsg %ansi(bold,yellow)Auto-Standing and resuming.}
    #ALIAS zspRMSpellupFinished {zspMsg %ansi(bold,yellow)Spellup %ansi(bold,white)@zspRRunProfName %ansi(bold,yellow)Finished Successfully.}

#CLASS 0

#CLASS {ZSpellup|Spellup|Triggers} {disable}
    #TRIGGER {Sorry, you can't do that.} {zspRCastNextSpellError}
    #TRIGGER {You have not practiced that spell!} {zspRCastNextSpellError}
   
    #TRIGGER {Sparkles of light fill the area, as the magic is absorbed into the surroundings.} {zspRPausing No Magic Room, please leave and resume spellup}
    #TRIGGER {The battle distracts you from your spell casting.} {zspRPausing You are in combat please resume spellup when finished.}
    #TRIGGER {You can't summon enough energy to cast the spell.} {zspRPausing Not Enough Mana Pausing, tick and resume spellup.}
    #TRIGGER {You dream of accomplishing such great and wonderous feats.} {zspRPausing Your sleeping please wake up and resume spellup.}
   
    #TRIGGER {That is impossible to do while sitting.} {zspRStandCast}
    #TRIGGER {You have to stand up before you can do that.} {zspRStandCast}

    #TRIGGER {You chant out the arcane words and are drained of %d mana.} {zspRCastNextSpellSuccess}
    #TRIGGER {You fumble over the correct inflection *}  {zspRCastSameSpellFailure}
#CLASS 0

#T- {ZSpellup|Spellup|Triggers}


You can just read this in it will delete the old zspellup class first, this will delete your old profiles though so if you want to try and save them remove the first line then read it in, should work fine if it doesnt then delete the old zspellup class and read it in.

Cheers Caebryn
Reply with quote
jessew
Apprentice


Joined: 03 Mar 2003
Posts: 141

PostPosted: Wed Dec 17, 2003 5:51 pm   
 
Thanks guys :)

Tlaca, one way of doing it would be to have an alias to cast sanc
which checked aff right after it casted since i think a tick is a set
time for everyone, 32 seconds? not positive i need to check it again
then create a countdown timer from that information on the status bar. I'll write a little script and see if it works.

Carabas, thanks, I would be interested in seeing any changes you make to your spellup script

Cheers Caebryn
Reply with quote
Carabas
GURU


Joined: 28 Sep 2000
Posts: 434
Location: USA

PostPosted: Wed Dec 17, 2003 6:25 pm   
 
The sanc timer was part of the protection module in the Combat Notification System. Feel free to rip it apart to create a standalone script.
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Wed Dec 17, 2003 9:57 pm   
 
For multiple strength I just added strength to the list a couple more times.
Not very cool I know, but it gets the job done [:p]

Thanks Carabas, I'll take a look and see what I can do with it Cool

Tlaca
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Wed Dec 17, 2003 10:28 pm   
 
OK, all I did really was rape your script Carabas.

Here's what I came up with, and it seems to work.

#CLASS {Combat Notification|Protection}
#ALARM "Prot_Timer" -:*01 {#if (@ProtTix_Sanc) {#add ProtTix_Sanc -1};#if (@ProtTix_MShield) {#add ProtTix_MShield -1};#if (@ProtTix_FShield) {#add ProtTix_FShield -1};#if (@ProtTix_Images) {#add ProtTix_Images -1}}
#CLASS 0

#CLASS {Combat Notification|Protection|Status Bars}
#STAT {Protection -%if(%null(@Prot)," none - ")} "" "Prot"
#STAT {Sanctuary: @{ProtTix_Sanc}sec -} "" "Prot_Sanc"
#STAT {Images: @ProtTix_NumImages - @{ProtTix_Images}sec -} "" "Prot_Images"
#STAT {Mana Shield: @{ProtTix_MShield}sec -} "" "Prot_MShield"
#STAT {Fireshield: @{ProtTix_FShield}sec -} "" "Prot_FShield"
#CLASS 0

#CLASS {Combat Notification|Protection|Triggers}
#TRIGGER {^A deep red shield of fire surrounds you.$} {Prot = %additem(FShield,@Prot);Prot = %dups(@Prot);ProtTix_FShield = 150;#T+ Prot_FShield}
#TRIGGER {^You have been KILLED!!$} {Prot = %null;#T- Prot_Sanc;#T- Prot_FShield;#T- Prot_MShield;#T- Prot_Images}
#TRIGGER {^Your shield of fire collapses.$} {Prot = %delitem(FShield,@Prot);Prot = %dups(@Prot);ProtTix_FShield = 0;#T- Prot_FShield}
#TRIGGER {^Your magical energy expands and hardens into a crackling blue shield which surrounds you.$} {Prot = %additem(MShield,@Prot);Prot = %dups(@Prot);ProtTix_MShield = 120;#T+ Prot_MShield}
#TRIGGER {^Your Mana Shield crackles, shrinks momentarily and dissipates.$} {Prot = %delitem(MShield,@Prot);Prot = %dups(@Prot);ProtTix_MShield = 0;#T- Prot_MShield}
#TRIGGER {^Your Mana Shield crackles and fizzles out.$} {Prot = %delitem(MShield,@Prot);Prot = %dups(@Prot);ProtTix_MShield = 0;#T- Prot_MShield}
#TRIGGER {^Your Mana Shield cracks and pops out.$} {Prot = %delitem(MShield,@Prot);Prot = %dups(@Prot);ProtTix_MShield = 0;#T- Prot_MShield}
#TRIGGER {^A glowing white aura surrounds your body.$} {Prot = %additem(Sanc,@Prot);Prot = %delitem(FShield,@Prot);Prot = %dups(@Prot);ProtTix_FShield = 0;#T+ Prot_Sanc;#T- Prot_FShield;#T+ get_sanc_tix;sc a}
#TRIGGER "get_sanc_tix" {^ sanctuary : Duration - (%d) ticks} {ProtTix_Sanc = %eval((%1*30)+30);#T- get_sanc_tix}
#TRIGGER {^Your shield of fire slowly dissipates....and blinks out.$} {Prot = %delitem(FShield,@Prot);Prot = %dups(@Prot);ProtTix_FShield = 0;#T- Prot_FShield}
#TRIGGER {^The white aura around your body fades.$} {Prot = %delitem(Sanc,@Prot);Prot = %dups(@Prot);ProtTix_Sanc = 0;#T- Prot_Sanc}
#TRIGGER {^Your white aura flashes brightly and vanishes.$} {Prot = %delitem(Sanc,@Prot);Prot = %dups(@Prot);ProtTix_Sanc = 0;#T- Prot_Sanc}
#TRIGGER {^Your white aura flashes brightly and disappears.$} {Prot = %delitem(Sanc,@Prot);Prot = %dups(@Prot);ProtTix_Sanc = 0;#T- Prot_Sanc}
#TRIGGER {^Several illusionary images, duplicates of yourself, appear around you.$} {Prot = %additem(Images,@Prot);Prot = %dups(@Prot);#T+ Prot_Images;#T+ get_image_tix;sc a}
#TRIGGER {^Your illusionary doubles vanish.$} {#T- Prot_Images;Prot = %delitem(Images,@Prot);Prot = %dups(@Prot);ProtTix_Images = 0}
#TRIGGER "get_image_tix" {^ phantasmal image : Duration - (%d) ticks, (%d) images$} {ProtTix_Images = %eval((%1*30)+30);ProtTix_NumImages = %2;#T- get_image_tix}
#TRIGGER {^(*)'s attack has destroyed one of your illusionary images.$} {#add ProtTix_NumImages -1;#if (@ProtTix_NumImages = 0) {#T- Prot_Images;Prot = %delitem(Images,@Prot);Prot = %dups(@Prot);ProtTix_Images = 0}}
#TRIGGER {^Your illusionary duplicates vanish with a bright spark of energy.$} {#T- Prot_Images;Prot = %delitem(Images,@Prot);Prot = %dups(@Prot);ProtTix_Images = 0}
#TRIGGER {Poof! You arrive in the social area.} {#T- Prot_Timer}
#TRIGGER {Poof, You are back to reality.} {#T+ Prot_Timer}
#CLASS 0

#CLASS {Combat Notification|Aliases|Protection}
#ALIAS rsProt {#T- Prot_Sanc;#T- Prot_Images;#T- Prot_MShield;#T- Prot_FShield;ProtTix_Sanc=0;ProtTix_FShield=0;ProtTix_MShield=0;ProtTix_Images=0;ProtTix_NumImages=0;Prot=%null;#SHOW {%char(10)@ansi(bYellow)Protection status has been reset.@ansi()}}
#CLASS 0

#CLASS {Combat Notification|Variables|Protection}
#VAR ProtTix_Sanc {0}
#VAR ProtTix_FShield {0}
#VAR ProtTix_MShield {0}
#VAR ProtTix_Images {0}
#VAR ProtTix_NumImages {0}
#CLASS 0

I bear no claim to this, it is simply cut and paste from Carabas's combat
script. It even seems to work with Caebryns spellup [8D]

When I get my Wring of Winter's Wrath, I will try and add Iceshield to that.

Tlaca
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Wed Dec 17, 2003 10:35 pm   
 
hmm..., it doesn't reset the seconds if you cast sanc before it wears off.
I'm guessing this to be because you don't get to trigger without seeing
'A glowing white aura surrounds you'

I guess it should really trigger on casting the spell, or on someone using orb.

Tlaca
Reply with quote
Electron
Wanderer


Joined: 20 Nov 2001
Posts: 72

PostPosted: Fri Dec 19, 2003 3:59 pm   
 
I added a faded spell status bar and an alias "rsp" to recast faded spells. I think some spell triggers are missing. These triggers have just been borrowed from Carabas script. If anyone knows anymore faded and dispelled triggers, please post them here.

Code:
#CLASS {ZSpellup}
#CLASS 0

#CLASS {ZSpellup|UserCommands}
#ALIAS spc {zspOptionMenu}
#ALIAS sp {#IF (@zspRPaused) {zspRResume} {#IF (%null(%1)) {#IF (!%null(@zspPDefault)) {zspRRunProfName = @zspPDefault;zspRProfToRun = %eval(@@zspPDefault);zspRStart} {zspMNDP}} {#IF (%ismember(%1,@zspProfiles)) {zspRRunProfName = %eval(%1);zspRProfToRun = %eval(@%1);zspRStart} {zspMNSP %1}}}}
#ALIAS spr {zspRBRunning = 0;zspRPaused = 0;zspMSRT}
#ALIAS spp {#IF (@zspRPaused) {zspMAPS} {#IF (@zspRBRunning) {zspRPaused = 1;zspRMPausing;#T- {ZSpellup|Spellup|Triggers}} {zspMNBR}}}
#ALIAS rsp {#IF (%null( %1)) {#IF (%numitems( @zspFFadedSpells)) {#IF (@zspRPaused) {zspRResume} {zspRProfToRun = @zspFFadedSpells;zspRStart;#VARIABLE zspFFadedSpells {%null}}} {#SHOW {%char( 10)@ansi(White)Spellup Error%char( 10)%char( 10)@ansi(dGreen)There are no faded spells in the list.}}};#IF ("%1" = "clear") {#VARIABLE zspFFadedSpells {%null}}}
#CLASS 0

#CLASS {ZSpellup|PickList Creator}
#ALIAS zspCreateList {zspPickList = "";#FORALL @zspFullList {#IF (%ismember(%i, %eval(@%1))) {zspPickList = %additem(%concat(*,%i),@zspPickList)} {zspPickList = %additem(%i,@zspPickList)}}}
#VAR zspPickList {""} {""}
#VAR zspFullList {armor|bless|breathe water|detect evil|detect good|detect invisibility|detect magic|fireshield|infravision|invisibility|levitate|manashield|map catacombs|phantasmal image|protection|quickness|sanctuary|sense life|shield|stone skin|strength}
#CLASS 0

#CLASS {ZSpellup|Profiles}
#ALIAS zspCheckProfile {#IF (%null(%1)) {zspConfigureProfile @zspPDefault} {#IF (%ismember(%1,@zspProfiles)) {zspConfigureProfile %1} {zspCreateNewProfile %1}}}
#ALIAS zspCreateNewProfile {zspConfigureProfile %1;#CLASS {ZSpellup|Profiles};#IF (%null(%eval(@%1))) {zspMNFA;#UNVAR {%1}} {#IF (%null(@zspPDefault)) {zspPDefault = %1;zspMADF %1};zspProfiles = %additem(%1, @zspProfiles);zspMNFS %1;#CLASS 0}}
#ALIAS zspConfigureProfile {zspCreateList %1;#CLASS {ZSpellup|Profiles};#VARIABLE {%1} {%pick(@zspPickList)};#CLASS 0}
#ALIAS zspCDefaultProfile {#IF (%null( @zspProfiles)) {zspMNPR} {zspPTemp = %pick( "p:Choose default profile", "o:1", %if( %null( @zspPDefault), @zspProfiles, %replaceitem( %concat( *, @zspPDefault), %ismember( @zspPDefault, @zspProfiles), @zspProfiles)));#IF (%null( @zspPTemp) | (@zspPTemp = @zspPDefault)) {zspMDNC} {zspPDefault = @zspPTemp;zspMDCS %1}}}
#ALIAS zspCModifyProfile {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to Modify","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAMP} {zspCreateList @zspPTemp;zspPTmpProf = %pick("p:Make changes to profile",@zspPickList);#IF (%null(@zspPTmpProf)) {zspMPNM} {#VARIABLE @zspPTemp {@zspPTmpProf};zspMPMS}}}}
#ALIAS zspCRenameProfile {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to rename","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMARP} {zspPTmpName = "";zspPTmpName = %prompt("","Enter New Name For Profile");#IF (%null(@zspPTmpName)) {zspMarp} {#CLASS {ZSpellup|Profiles};#VARIABLE {@zspPTmpName} {%eval(@@zspPTemp)};zspProfiles = %delitem(@zspPTemp,@zspProfiles);zspProfiles = %additem(@zspPTmpName,@zspProfiles);#UNVAR {@zspPTemp};#IF (@zspPDefault == @zspPTemp) {zspPDefault = @zspPTmpName};zspMRPS @zspPTemp @zspPTmpName}}}}
#ALIAS zspCRunAProfile {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to run","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMAEP} {sp @zspPTemp}}}
#ALIAS zspCDeleteProfile {#IF (%null(@zspProfiles)) {zspMNPR} {zspPTemp = %pick("p:Choose Profile to delete","o:1",@zspProfiles);#IF (%null(@zspPTemp)) {zspMADP} {#CLASS {ZSpellup|Profiles};#UNVAR {%eval(@zspPTemp)};zspProfiles = %delitem(@zspPTemp,@zspProfiles);#CLASS 0;zspMDPS @zspPTemp;#IF (@zspPDefault == @zspPTemp) {#IF (%null(@zspProfiles)) {zspPDefault = "";zspMDNP} {zspMDDP;zspPDefault = "";zspCDefaultProfile}}}}}
#VAR zspPDefault {Efisticus}
#VAR zspProfiles {Efisticus}
#VAR zspPTemp {Efisticus}
#VAR zspPTmpProf {armor|bless|breathe water|detect evil|detect good|detect invisibility|detect magic|infravision|levitate|quickness|sense life}
#VAR zspPTmpName {""}
#VAR Efisticus {armor|bless|breathe water|detect evil|detect good|detect invisibility|detect magic|infravision|levitate|quickness|sense life}
#CLASS 0

#CLASS {ZSpellup|Configuration Manager}
#ALIAS zspOptionMenu {zspCTemp = %ismember(%pick("p:ZSpellup Menu","o:1",@zspConfigList),@zspConfigList);#IF (@zspCTemp) {#CASE @zspCTemp {zspCNewProfile} {zspCModifyProfile} {zspCDefaultProfile} {zspCDeleteProfile} {zspCRenameProfile} {zspCRunAProfile}}}
#ALIAS zspCNewProfile {zspCTemp = %prompt("", "Enter Name for New Profile");#IF %null(@zspCTemp) {zspMADF %1} {#IF (%ismember(@zspCTemp,@zspProfiles)) {zspMPNE} {zspCreateNewProfile @zspCTemp}}}
#VAR zspCTemp {""} {""}
#VAR zspConfigList {"Create New Profile"|"Modify Existing Profile"|"Choose New Default Profile"|"Delete A Profile"|"Rename A Profile"|"Run A Profile"}
#CLASS 0

#CLASS {ZSpellup|Messages}
#ALIAS zspMsg {#SHOW @zspLogo %ansi(bold,green)%-1}
#ALIAS zspErrMsg {#SHOW @zspLogo %ansi(bold,red)Error: %ansi(bold,green) %-1}
#ALIAS zspMNBR {zspErrMsg You are not running a profile now.}
#ALIAS zspMAPS {zspErrMsg Spellup is already paused, use %ansi(bold,white)sp to resume}
#ALIAS zspMNDP {zspErrMsg You have not set a default profile, please use menu system to select one.}
#ALIAS zspMDPS {zspMsg Successfuly deleted %ansi(bold,white)%1 %ansi(bold,green)profile.}
#ALIAS zspMDNP {zspMsg You have no profiles, please create a new one.}
#ALIAS zspMDDP {zspMsg You have deleted your default profile, please select a new one.}
#ALIAS zspMADP {zspMsg Aborted Profile Delete.}
#ALIAS zspMAEP {zspMsg Aborted Running A Profile.}
#ALIAS zspMSRT {zspMsg Spellup has been reset.}
#ALIAS zspMNSP {zspErrMsg No such profile %ansi(bold,white)%1%ansi(bold,green).}
#ALIAS zspMRPS {zspMsg Profile %ansi(bold,white)%1 %ansi(bold,green)renamed to %ansi(bold,white)%2}
#ALIAS zspMARP {zspMsg Aborted Profile Rename}
#ALIAS zspMPMS {zspMsg Profile %ansi(bold,white)@zspPTemp%ansi(bold,green) modified successfully.}
#ALIAS zspMPNM {zspMsg Profile not modified}
#ALIAS zspMAMP {zspMsg Aborted Modifying Profile}
#ALIAS zspMDNC {zspMsg Default profile not changed from %ansi(bold,white)@zspPDefault}
#ALIAS zspMDCS {zspMsg Default profile now is %ansi(bold,white)@zspPDefault}
#ALIAS zspMNPR {zspErrMsg You have no profiles, you can create one through the option menu.}
#ALIAS zspMNFA {zspMsg Create New Profile Aborted}
#ALIAS zspMPNE {zspErrMsg Profile With That Name Already Exists}
#ALIAS zspMADF {zspMsg %ansi(bold,white)%1 %ansi(bold,green)Set to default profile automatically. You can change this through ZSpellup Option Menu}
#ALIAS zspMNFS {zspMsg New Profile %ansi(bold,white)%1 %ansi(bold,green)created successfully.}
#VAR zspLogo {%ansi(bold,blue)(%ansi(bold,white)ZSpellup V2.0%ansi(bold,blue))}
#CLASS 0

#CLASS {ZSpellup|Spellup}
#ALIAS zspRStart {zspRBRunning = 1;#T+ {ZSpellup|Spellup|Triggers};zspRCurSpell = 1;zspRMStart;zspRCastSameSpellStart}
#ALIAS zspRResume {#T+ {ZSpellup|Spellup|Triggers};zspRPaused = 0;zspRMResume;zspRCastSameSpellStart}
#ALIAS zspRCastNextSpellError {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMErrorCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
#ALIAS zspRCastNextSpellSuccess {#ADD zspRCurSpell {1};#IF (@zspRCurSpell > %numitems(@zspRProfToRun)) {zspRSpellupFinished} {zspRMSuccessCastNext;cast %item(@zspRProfToRun,@zspRCurSpell)}}
#ALIAS zspRCastSameSpellFailure {zspRMCastSame;cast %item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRCastSameSpellStart {zspRMCastSameStart;cast %item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRSpellupFinished {#T- {ZSpellup|Spellup|Triggers};zspRMSpellupFinished}
#ALIAS zspRStandCast {zspRMStand;stand;zspRCastSameSpellStart}
#ALIAS zspRPausing {#T- {ZSpellup|Spellup|Triggers};zspRMPausing}
#ALIAS zspRMStart {zspMsg Executing Spellup using profile: %ansi(bold,white)@zspRRunProfName}
#ALIAS zspRMResume {zspMsg Resuming Spellup using profile: %ansi(bold,white)@zspRRunProfName}
#ALIAS zspRMCastSame {zspMsg %ansi(bold,red)Failure %ansi(bold,green)Recasting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRMCastSameStart {zspMsg Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRMErrorCastNext {zspMsg %ansi(bold,red)Failure %ansi(bold,green)skipping %ansi(bold,white)%item(@zspRProfToRun,%eval(@zspRCurSpell-1)) %ansi(bold,green)Now Casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRMSuccessCastNext {zspMsg %ansi(bold,cyan)Success %ansi(bold,green)now casting %ansi(bold,white)%item(@zspRProfToRun,@zspRCurSpell)}
#ALIAS zspRMPausing {zspMsg %ansi(bold,yellow)Pausing Spellup %ansi(bold,green)%-1;zspRPaused = 1}
#ALIAS zspRMStand {zspMsg %ansi(bold,yellow)Auto-Standing and resuming.}
#ALIAS zspRMSpellupFinished {zspMsg %ansi(bold,yellow)Spellup %ansi(bold,white)@zspRRunProfName %ansi(bold,yellow)Finished Successfully.}
#VAR zspRProfToRun {quickness} {""}
#VAR zspRRunProfName {""} {""}
#VAR zspRPaused {0} {0}
#VAR zspRCurSpell {2} {0}
#VAR zspRBRunning {1} {0}
#CLASS 0

#CLASS {ZSpellup|Spellup|Triggers} {disable}
#TRIGGER {Sorry, you can't do that.} {zspRCastNextSpellError}
#TRIGGER {You have not practiced that spell!} {zspRCastNextSpellError}
#TRIGGER {Sparkles of light fill the area, as the magic is absorbed into the surroundings.} {zspRPausing No Magic Room, please leave and resume spellup}
#TRIGGER {The battle distracts you from your spell casting.} {zspRPausing You are in combat please resume spellup when finished.}
#TRIGGER {You can't summon enough energy to cast the spell.} {zspRPausing Not Enough Mana Pausing, tick and resume spellup.}
#TRIGGER {You dream of accomplishing such great and wonderous feats.} {zspRPausing Your sleeping please wake up and resume spellup.}
#TRIGGER {That is impossible to do while sitting.} {zspRStandCast}
#TRIGGER {You have to stand up before you can do that.} {zspRStandCast}
#TRIGGER {You chant out the arcane words and are drained of %d mana.} {zspRCastNextSpellSuccess}
#TRIGGER {You fumble over the correct inflection *} {zspRCastSameSpellFailure}
#CLASS 0

#CLASS {ZSpellup|Faded Spells Management}
#ALIAS zspAddFaded {#IF (%ismember( %-1, @zspPTmpProf)) {#ADDITEM zspFFadedSpells {%-1};#VARIABLE zspFFadedSpells {%dups( @zspFFadedSpells)}}}
#VAR zspFFadedSpells {} {""}
#STAT {Faded Spells: %if(@zspFFadedSpells,%replace(@zspFFadedSpells,"|",", "),none)}
#CLASS 0

#CLASS {ZSpellup|Faded Spells Management|Faded Spells}
#TRIGGER {A spectral image of a raven emerges from your body, flying away.} {zspAddFaded bless}
#TRIGGER {The bright burst of colors has blinded you!} {zspAddFaded cure blind}
#TRIGGER {The detect invisible wears off.} {zspAddFaded detect invisibility}
#TRIGGER {You can no longer see in the dark.} {zspAddFaded infravision}
#TRIGGER {You feel less aware of your surroundings.} {zspAddFaded sense life}
#TRIGGER {You feel less protected.} {zspAddFaded armor}
#TRIGGER {You feel more vulnerable.} {zspAddFaded protection from evil}
#TRIGGER {You feel the protective veil of darkness vanish.} {zspAddFaded protection from good}
#TRIGGER {You feel very sick.} {zspAddFaded remove poison}
#TRIGGER {You feel weaker.} {zspAddFaded strength}
#TRIGGER {You feel yourself exposed.} {zspAddFaded invisibility}
#TRIGGER {You have been blinded!} {zspAddFaded cure blind}
#TRIGGER {You sense the blue in your vision disappear.} {zspAddFaded detect good}
#TRIGGER {Your endurance returns to normal.} {zspAddFaded quickness}
#TRIGGER {Your force shield shimmers then fades away.} {zspAddFaded shield}
#TRIGGER {Your levitation wears off.} {zspAddFaded levitate}
#TRIGGER {Your lungs feel like they are on fire as the breathe water spell wears off.} {zspAddFaded breathe water}
#TRIGGER {Your shield of fire slowly dissipates....and blinks out.} {zspAddFaded fireshield}
#CLASS 0

#CLASS {ZSpellup|Faded Spells Management|Dispelled Spells}
#TRIGGER {A spectral raven emerges from your body, forced out by magic.} {zspAddFaded bless}
#TRIGGER {You can no longer detect magic.} {zspAddFaded detect magic}
#TRIGGER {Your skin feels like stone no longer.} {zspAddFaded stone skin}
#TRIGGER {You feel exposed.} {zspAddFaded invisibility}
#TRIGGER {You don't feel so strong.} {zspAddFaded strength}
#TRIGGER {Your protective veil of darkness has been shattered.} {zspAddFaded protection from good}
#TRIGGER {Your magical shield has been dispelled.} {zspAddFaded shield}
#TRIGGER {Your shield of fire collapses.} {zspAddFaded fireshield}
#TRIGGER {Your lungs heave and you cough water.} {zspAddFaded breathe water}
#TRIGGER {You don't feel lighter than air any more.} {zspAddFaded levitate}
#TRIGGER {Your ability to detect evil auras has been dispelled.} {zspAddFaded detect evil}
#TRIGGER {Your ability to detect good auras has been dispelled.} {zspAddFaded detect good}
#TRIGGER {You feel less morally protected.} {zspAddFaded protection from evil}
#TRIGGER {You feel less perceptive.} {zspAddFaded detect invisibility}
#TRIGGER {You feel less in touch with living things.} {zspAddFaded sense life}
#TRIGGER {Your sight grows dimmer.} {zspAddFaded infravision}
#TRIGGER {You don't feel so well protected.} {zspAddFaded armor}
#CLASS 0
Reply with quote
Carabas
GURU


Joined: 28 Sep 2000
Posts: 434
Location: USA

PostPosted: Fri Dec 19, 2003 9:29 pm   
 
#STAT {Faded Spells: %if(@zspFFadedSpells,%replace(@zspFFadedSpells,"|",", "),none)}

With the edition of %expandlist since the last time I updated my script, we can do this:

#STAT {Faded Spells: %if(@zspFFadedSpells,%expandlist(@zspFFadedSpells,", "),none)}

I know thats nothing major, but for someone new to zscript, %expandlist will probably make more since than using %replace
Reply with quote
Tlaca
Beginner


Joined: 11 May 2003
Posts: 23
Location: Canada

PostPosted: Tue Dec 30, 2003 8:50 pm   
 
I'm having a problem with zmud, and of course, zugg is not answering but reports over the holidays.
Everyime I read 0:59:59 for time online, it pops up an error box
indicating an illegal operation. I hit ok, and it comes up with
an EConvertError or something like that. I'm wondering if there is
a trigger in the spellup script or maybe the stat one that I raped from
Carabas' that might cause a problem at 1:00:00 online time. I've searched
through a bit, but don't see anything. I've even uninstalled and re-installed
including upgrades, and no effect.

Tlaca
Reply with quote
Carabas
GURU


Joined: 28 Sep 2000
Posts: 434
Location: USA

PostPosted: Thu Jan 01, 2004 7:42 pm   
 
This may or may not be the solution. A friend of mine had this exact same problem. We tried everything, even disabled the trigger/command parsers for an hour and it still happened. We never tried unlicensing zMUD, so that may be the key.
Reply with quote
Display posts from previous:   
Post new topic   Reply to topic     Home » Forums » Finished MUD Scripts All times are GMT
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

© 2009 Zugg Software. Hosted by Wolfpaw.net