Zugg Software :: View topic

Beginner Joined: 01 Jan 2002 Posts: 10 Location: USA

i saw how zchat text shows up on your mud screen and i wanted it to do the same for mIRC so i wrote this little script, its mostly mIRC heavy and it uses DDE(dynamic data exchange) wich is the devil, but it gets the job done. IF you dont know what mIRC is go here www.mirc.co.uk

What it dose........
This script makes windows in Zmud wich act like mIRC channels, mIRC fills these windows with the text in its channels via DDE, it will support as many channels as you like providing Zmud supports that many windows letting you see whats being said in mIRC and chat along while your in Zmud.

The commands......
This script always defaults to off, turn it on first
zmirc [on/off]

to chat while in zmud the command is
irc [channel] [text]
wich would look like.....
irc #mud hello world!

to join a channel
jirc [channel]

to leave a channel
pirc [channel]

to op someone in a channel
opirc [channel] [name]

to deop....
deopirc [channel] [name]

to voice someone
virc [channel] [name]

to devoice
devirc [channel] [name]

anyways here is the script.........

[Paste this in zmud command line]
#ALIAS zmIRC {#if (%1 = off) {#DDE MIRC COMMAND {"/closeall"}};#DDE MIRC COMMAND {"//set %zmIRC" %1}}
#ALIAS irc {#DDE MIRC COMMAND {"//msg" %1 %-2};#WIN %1 %ansi( yellow, black)You say: %-2}
#ALIAS opirc {#DDE MIRC COMMAND {"//mode" %1 %2 "+o"}}
#ALIAS jirc { #DDE MIRC COMMAND {"//join" %1} }
#ALIAS deopirc { #DDE MIRC COMMAND {"//mode" %1 %2 "+o"}}
#ALIAS virc { #DDE MIRC COMMAND {"//mode" %1 %2 "+v"}}
#ALIAS devirc { #DDE MIRC COMMAND {"//mode" %1 %2 "-v"}}
#ALIAS pirc { #DDE MIRC COMMAND {"//part" %1}}

[Past this in mIRC aliases]
/closeall {
%channel = 1
while ($chan(%channel) != $null) {
/part $chan(%channel)
/dde -e ZMUD ZMUD #cl $chan(%channel)
inc %channel
}
}
/chngtxt {
%newtxt = $replace($strip($1),~,$chr(126),",~",;,~;,[,~[,],~],%,~%,@,~@,~{,~{,~},~})
return %newtxt
}

The remote part is too large to fit in this
post, il make another.

Beginner Joined: 01 Jan 2002 Posts: 10 Location: USA

[Paste this part in remote in mIRC]
on 1:TEXT:*:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan $chr(37) $+ ansi(yellow,black) $+ $chngtxt($nick) $+ : $chr(37) $+ ansi(grey,black) $+ $chngtxt($1-)
}
}
on 1:NICK: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: *** $chngtxt($nick) is now known as $chngtxt($newnick)
}
}
on 1:TEXT:*:?: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #ECHO mIRC: $chngtxt($nick) tells you $chngtxt($1-)
}
}

on 1:JOIN:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) has joined $chngtxt($chan)
}
}
on 1:PART:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) has left $chngtxt($chan)
if ($nick = $me) {
/dde -e ZMUD ZMUD #cl $chan
}
}
}
on 1:DEOP:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode -o $chngtxt($opnick)
}
}
on 1:OP:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode +o $chngtxt($opnick)
}
}
on 1:KICK:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($knick) has been kicked by $chngtxt($nick), $chngtxt($1-)
if ($knick = $me) {
/dde -e ZMUD ZMUD #Cl $chan
/dde -e ZMUD ZMUD #echo mIRC: *** You have been kicked from $chngtxt($chan) by $chngtxt($nick) $+ , $chngtxt($1-)
}
}
}
on 1:VOICE:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode +v $chngtxt($vnick)
}
}
on 1:DEVOICE:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode -v $chngtxt($vnick)
}
}
on @1:MODE:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets channel mode to: $chngtxt($1-)
}
}
on 1:ACTION:*:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan * $+ $chngtxt($nick) $chngtxt($1-)
}
}
on 1:INPUT:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan $chr(37) $+ ansi(yellow,black) $+ $chngtxt($nick) $+ : $chr(37) $+ ansi(grey,black) $+ $chngtxt($1-)
}
}
on 1:QUIT: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: $chngtxt($nick) has quit IRC (Quit: $chngtxt($1-) $+ )
}
}
on 1:TOPIC:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets topic to $chngtxt($1-)
}
}
on 1:BAN:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode $chngtxt($1-)
}
}
on 1:UNBAN:#: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #win $chan *** $chngtxt($nick) sets mode $chngtxt($1-)
}
}
on 1:EXIT: {
if (%zmirc = on) {
set %zmIRC off
closeall
}
}
on 1:CONNECT:/set %zmIRC off
RAW 474:*: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: $1-
}
}
RAW 471:*: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: $1-
}
}
RAW 473:*: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: $1-
}
}
RAW 475:*: {
if (%zmIRC = on) {
/dde -e ZMUD ZMUD #echo mIRC: $1-
}
}

Beginner Joined: 01 Jan 2002 Posts: 10 Location: USA

Ok its all there, now, alot of that is word wraped so if you dont have an eye for code and would like a .txt file send me an email and il be glad to send it to you Sinrae@hotmail.com

this is a finished script only because i dont want to waste any more time with it, it could however be "more finished" but thats a job for...errrr.....ummm.....someone else.

PROBLEMS:
closing zmud without turning the script off will result in mIRC freezing. trying to use any of the IRC commands from zmud while mIRC is NOT open will result in zmud freezing. mIRC color codes are all striped out before it gets to zmud, i was working on a mirc color code to ANSI script for it but i lost intrest.

tips:
closing mIRC before zmud prevents freeze and also cleans up rather nicely. Always turn the script on from Zmud. If you do happen to make it freeze up just alt+ctrl+del and end task on wichever froze, too bad if you wanted to save, i told u DDE was the devil at the begining didnt i? Use the most recent versions of mIRC and Zmud. ALL of the command and identifiers from mIRC SHOULD be taken literal wich means no one can make zmud do crazy stuff by typing in the right thing in an IRC channel, however i havent tested this to its limits, i trust it tho.

If for some reason this script makes your computer burst into flames and explode destroying your house along with your neighbors car and the fire department trace the explosion back to my script and the nice men in blue jackets come to my door and arrest me and my cat. Then i didnt do it, my cat didnt do it, so dont send any hate mail to me and worst of all pls dont make my cat have to learn how to read and write just to reply to all your hate mail. Leave nibbles alone. Most of all enjoy! but still, keep nibbles out of this!

Beginner Joined: 01 Nov 2002 Posts: 24 Location: Sweden

(untested)
In the alias menu:
View-> Show Inherited
Go into the Systems folder
in the "atexit" alias put "zmirc off"

Should solve the freeze problem if you forget to turn it off.

zMUD 6.16 - scobie@linux.se