Zugg Software :: View topic

GURU Joined: 26 Jul 2001 Posts: 1958 Location: Canada

quote:

BTSuite is a collection of softwares that collectively act as a graphical client to BattleTech MUXs: a HUD(BTHUD), a Map Editor(LandDesign) and a Navigation tool(Mapper).

By using Mav's (Tuncay Goncuoglu) LandDesign you can create/modify a map of your scenario.

Using Mav's BTHUD will help you manage battlefield unit position/headings/speeds to give you a good grasp of what is happening on that map. It will also track contact lists, damage taken and damage delivered.

Interfacing with Mav's BTHUD can be done with COM object interface.
[url="http://btsuite.sourceforge.net/files/ZHUDv1.8.zip
"]Interface by Michael Masters[/url]
Interface by Momfer as seen below

Understand that a new protocol is being created for BattleTech MUX called hudinfo. Be wary that newer versions of BTHUD will most likely use hudinfo over the traditional commands.

Ton Diening

GURU Joined: 26 Jul 2001 Posts: 1958 Location: Canada

This was done by Momfer at 3030 to interface zMud to Mav's BTHUD.

Note that Momfer uses the special characters ^ instead of @
BattleTech MUX has many commands that start with ! + . @ etc so adjust your special
characters accordingly.

#CLASS {BtSuite}
#ALIAS HON {#if (^HUDLoaded<>0) {#TS 10;#TI 1 +ss}}
#ALIAS RepCon {#if (^HUDLoaded<>0) {sendchannel %Lower( ^CONReportChannel)=%comget( HUD, "ReportCon", %trim( %1))} {#SHOW "HUD Not Loaded"}}
#ALIAS CheckCon {#if (^HUDLoaded<>0) {#SHOW %comget( HUD, "ReportCon", %trim( %1))} {#SHOW "HUD not Loaded"}}
#ALIAS ListAllCons {#if (^HUDLoaded<>0) {#SHOW ContactList:%{crlf}%comget( HUD, ListContacts)} {#SHOW "HUD not Loaded"}}
#ALIAS LostAll {#if (^HUDLoaded<>0) {#COM HUD LostAllCons}}
#ALIAS InitChar {&CMD_SS me=$+ss:status s ;| think [setq(0,BT::%|)];contacts !b ;| think [eval([edit([translate(translate(stripansi(%q0%|),1),1)],%r,%rBT::)])]
}
#ALIAS HOFF {#TI 0}
#ALIAS SetWorldMap {WordFile = %1;#Show World File is Set to ^WorldFile}
#ALIAS CloseHUD {#if (^HUDLoaded<>0) {#VAR HUD "";#VAR HUDLoaded 0;#SHOW "HUD Closed"} { #SHOW "HUD Already Closed"}}
#ALIAS SetCONChannel {#if (%len( %1)<1) {#SHOW "Invalid contact report channel selected."} {#VAR CONReportChannel %upper( %left( %1, 1));#SHOW "Contact report channel is set to "^CONReportChannel"."}}
#ALIAS LoadHUD {#if (^HUDLoaded<>1 and %trim( ^Worldfile)<>"") {#VAR HUD %comcreate( "BTSUITE.HUD");#COM HUD LoadMap ^WorldFile;#VAR HUDLoaded 1;#SHOW "HUD Loaded with map:";#SHOW ^WorldFile} {#SHOW "Errorr!!!";#SHOW "World file not set or map already loaded. Please";#SHOW "specify your world file first, using the setworldmap";#SHOW "command. If hud is already loaded, unload it first";#SHOW "by using the closehud command"}}
#ALIAS CloseMap {#if (^MAPLoaded<>0) {#VAR MAP "";#SHOW "Map has been closed";#VAR MAPLoaded 0} {#SHOW "MAP Already Closed"}}
#ALIAS SetLocation {#if (^HUDLoaded<>0) {#COM HUD SetMechStatus ^x ^y ^z ^a_hdg ^d_hdg ^a_spd ^d_spd ^c_ht ^m_ht ^st};#if (^MAPLoaded<>0) {#COM MAP SetLocation ^x ^y ^z ^a_hdg ^a_spd}}
#ALIAS SetContact {#if (^HUDLoaded<>0) {#if (%begins( ^strContact, "BT::")) {#COM HUD SetContactLine %expand( %rightback( %expand( ^strContact, 1), %len( %expand( ^strContact, 1))-4), 1)} {#COM HUD SetContactLine %expand( ^strContact, 1)}}}
#ALIAS RedrawMap {#if (^HUDLoaded<>0) {#COM HUD Redraw}}
#ALIAS LostContact {#if (^HUDLoaded<>0) {#COM HUD LostContact %1}}
#ALIAS ClearCons {#if (^HUDLoaded<>0) {#SHOW "Contact List Cleared";#COM HUD ClearCons}}
#ALIAS Toggle {#if (^HUDLoaded<>0) {#COM HUD Toggle %1}}
#ALIAS LoadMap {#if (^MAPLoaded<>1 AND %trim( ^WorldFile)<>"") {#VAR MAP %comcreate( "BTSUITE.MAP");#COM MAP LoadMap ^WorldFile;#VAR MAPLoaded 1;#SHOW "Map Ready"} {#SHOW "Error!!!";#SHOW "World file not set or map already loaded. Please";#SHOW "specify your world map first, using the setworldmap";#SHOW "command. If map is already loaded, unload it first";#SHOW "by using the closemap command."}}
#VAR HUD {}
#VAR MAP {}
#VAR HUDLoaded {0} {0}
#VAR MAPLoaded {0} {0}
#VAR CheckMux {False} {False}
#VAR WorldFile {K:BattleTechBTSuiteWorldsGNMap.wld} {K:BattleTechBTSuiteWorldsGNMap.wld}
#VAR ss {}
#VAR CONReportChannel {A} {A}
#VAR strContact {BT::PS*[AP]B Al Victor x: 10 y: 7 z: 0 r: 3.9 b: 66 s: 0.0 h:240 S: DFS }
#TRIGGER {LOC: (*),(*),(*) HD: (*)/(*) SP: (*)/(*) HT: (*)/(*) ST:(*)} {#VAR x %1;#VAR y %2;#VAR z %3;#VAR a_hdg %4;#VAR d_hdg %5;#VAR a_spd %6;#VAR d_spd %7;#VAR c_ht %8;#VAR m_ht %9;#VAR st %10;SetLocation}
#TRIGGER {Line of Sight Contacts:} {LostAll}
#TRIGGER {{PS|P | S}?~[??]{B|Q|H|T|V|U|F} * x:* y:* z:* r:* b:* s:* h:* S:*} {#VAR strContact %line;SetContact}
#TRIGGER {BT::{PS|P | S}?~[??]{B|Q|H|T|V|U|F} * x:* y:* z:* r:* b:* s:* h:* S:*} {#GAG;#VAR strContact %line;SetContact}
#TRIGGER {BT::Line of Sight Contacts:} {#GAG;LostAll}
#TRIGGER {BT::End Contact List} {#GAG;RedrawMap}
#TRIGGER {BT::LOC: (*),(*),(*) HD: (*)/(*) SP: (*)/(*) HT: (*)/(*) ST:(*)} {#GAG;#VAR x %1;#VAR y %2;#VAR z %3;#VAR a_hdg %4;#VAR d_hdg %5;#VAR a_spd %6;#VAR d_spd %7;#VAR c_ht %8;#VAR m_ht %9;#VAR st %10;SetLocation}
#TRIGGER {You have lost * ~[(*)~] from you scanners. It was last in your *.} {LostContact %1}
#STAT {X: ^x Y: ^y Z: ^z H: ^a_hdg:^d_hdg SP: ^a_spd:^d_spd H: ^c_ht:^m_ht S:^st}
#CLASS 0

#CLASS {BtSuite|SetStatus}
#VAR x {5}
#VAR y {9}
#VAR z {0}
#VAR a_hdg {74}
#VAR d_hdg {0}
#VAR a_spd {0.0}
#VAR d_spd {0.0}
#VAR c_ht {10}
#VAR m_ht {300}
#VAR st {}
#CLASS 0

#CLASS {BtSuite|BtDamage}
#ALIAS OnTakeDamage {#if (^HUDLoaded<>0) {#COM HUD OnDamageTaken ^strLoc ^strAmount}}
#ALIAS OnDoDamage {#if (^HUDLoaded<>0) {#COM HUD OnDamageInflicted ^strLoc ^strAmount}}
#ALIAS ResetDamage {#if (^HUDLoaded<>0) {#COM HUD ResetDamage;#SHOW "Damage cleared"}}
#ALIAS ShortDamage {#if (^HUDLoaded<>0) {@fo me=@emit ~[name(me)~] looks at his quick damage log and hmms, 'Taken: %comget(HUD,TotalDamageTaken), Inflicted: %comget(HUD,TotalDamageInflicted)'} {#SHOW "HUD Not Loaded"}
}
#ALIAS ShowDamageInflicted {#if (^HUDLoaded<>0) {@emit ~[name(me)~] shows you the distribution of %comget(HUD,TotalDamageInflicted) point of damage he has INFLICTED:%r %comget(HUD, ShowDamageInflicted)} {#SHOW "HUD not loaded"}}
#ALIAS ShowDamageTaken {#if (^HUDLoaded<>0) {@emit ~[name(me)~] shows you the distribution of %comget(HUD, TotalDamageTaken) points of damage he has TAKEN:%r %comget(HUD, ShowDamageTaken)} {#SHOW "HUD not Loaded"}}
#VAR strAmount {} {}
#VAR strLoc {} {}
#TRIGGER {You have been hit for (*) points of damage in the (*)} {#VAR strLoc "%2";#VAR strAmount %1;OnTakeDamage}
#TRIGGER {You hit for (*) points of damage in the (*)} {#VAR strAmount %1;#VAR strLoc "%2";OnDoDamage}
#CLASS 0

#CLASS {BtSuite|BtHelp}
#ALIAS btHelp {#show " ";#show " BtSuite for zMud v6.xx";#show " Available Command Types ";#show " /Damage - To see damage related commands";#show " /Contact - To see contact related commands";#show " ";#show "As you see these commands have a / prefix each.";#show " "}
#ALIAS /Contact {#show " ";#show " Available Contact Related Commands:";#show " Rpt <id> - Reports contact on designated channel.";#show " ccon <id> - Displays the contact to you only.";#show " cons - List contacts list.";#show " setconchan c - Sets the channel on wich the contact";#show " is to be reported.";#show " /clearcons - Clears the contact list.";#show " ";#show " Note thet none of these commands have a / prefix, except for clearcons.";#show " "}
#ALIAS /Damage {#show " Available Damage Related Commands:";#show " /cd - Clears all damage counters";#show " /dt (Damage Taken) - Emits the Damage you took";#show " /di (Damage Inflicted) - Emits the Damage you inflicted";#show " /dam - Emits the shorted damage form";#show " ";#show "As you can see, these commands have a / prefix each.";#show " "}
#CLASS 0

#CLASS {BtSuite|BtCommands}
#ALIAS /cd {ResetDamage}
#ALIAS /dt {ShowDamageTaken}
#ALIAS /di {ShowDamageInflicted}
#ALIAS /dam {ShortDamage}
#ALIAS rpt {RepCon %1}
#ALIAS ccon {CheckCon %1}
#ALIAS cons {ListAllCons}
#ALIAS /clearcons {clearcons}
#CLASS 0

#CLASS {BtSuite|BtRolls}
#ALIAS RollDist {#loop 2,9 {#show %i " : " %eval( ^"roll"%i)};#loop 10,12 {#show %i ": " %eval( ^"roll"%i)}}
#ALIAS ClearRolls {#loop 2,12 {#VAR %eval( "roll"%i) 0}}
#VAR strBTH {} {}
#VAR strRoll {} {}
#VAR Roll4 {0} {0}
#VAR Roll5 {0} {0}
#VAR Roll6 {0} {0}
#VAR Roll7 {0} {0}
#VAR Roll8 {0} {0}
#VAR Roll9 {0} {0}
#VAR Roll10 {0} {0}
#VAR Roll11 {0} {0}
#VAR Roll12 {0} {0}
#VAR Roll2 {0} {0}
#VAR Roll3 {0} {0}
#CLASS 0