Zugg Software :: View topic

Apprentice Joined: 19 Jan 2002 Posts: 107

Hi,i have been reading how to make tiggers for auto spelling,and i think they are too hard for me,because they even check the spells u are affected by and spells u depending on that.
What i would like to get,is a tigger for make zmud spell just the spells i always use,i dont mind if i already have them,i will first get them off,so the way the mud works is that way:
if the spell works,there is always the same phrase for each spell,and if it doesnt works,there are 3 or 4 phrases.
so i would like zmud to repeat the spells which had the negative phrase,until they work,or i run out of mana. Tnx a lot for ur help =)

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

This is fairly simple. Make an alias to enable a spellup class (so you don't have the triggers on all the time) and cast the first spell. If needed, it can also create a variable to store the name of the current spell. Then make a trigger for each "spell doesn't work" phrase to cast the spell again and another trigger for the "spell does work" phrase to move on to the next spell. The last spell can turn the class off. You then need one more trigger which will turn off the class when you run out of mana.

#AL spellup {#T+ Spellup;#VAR spell spell1;cast spell1}

#CLASS Spellup
#TR {any spell failure message} {cast @spell}
#TR {first spell1 failure message} {cast spell1}
#TR {second spell1 failure message} {cast spell1}
#TR {third spell1 failure message} {cast spell1}
#TR {spell1 works message} {#VAR spell spell2;cast spell2}
#TR {first spell2 failure message} {cast spell2}
#TR {second spell2 failure message} {cast spell2}
#TR {spell2 works message} {#VAR spell spell3;cast spell3}
#TR {first spell3 failure message} {cast spell3}
#TR {second spell3 failure message} {cast spell3}
#TR {spell3 works message} {#SHOW Spellup finished!;#T- Spellup}
#TR {out of mana message} {#SHOW Spellup aborted, OUT OF MANA!!;#T- Spellup}
#CLASS 0

LightBulb
All scripts untested unless otherwise noted

Apprentice Joined: 19 Jan 2002 Posts: 107

Wow tnx a lot,ill work on it =)

Apprentice Joined: 19 Jan 2002 Posts: 107

im afraid i didnt explain it very well... (sorry about my english) i wanted to say that there are 4 same failure phrases for ALL the spells so the tiggers changes a lot... sorry again for that,and tnx a lot for ur help, Articnal =)

GURU Joined: 15 Jun 2001 Posts: 654 Location: USA

quote:

im afraid i didnt explain it very well... (sorry about my english) i wanted to say that there are 4 same failure phrases for ALL the spells so the tiggers changes a lot... sorry again for that,and tnx a lot for ur help, Articnal =)

Best solution in this case is probably a script that will check your affects when you get one of those 4 failure phrases and figure out what is missing. There have been a good many of those posted... a quick search for affects and spells should turn up a few.

- Charbal

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

No problem, just use the general failure trigger four times.

#TR {any spell failure message} {cast @spell}
#TR {any spell failure message2} {cast @spell}
#TR {any spell failure message3} {cast @spell}
#TR {any spell failure message4} {cast @spell}

Since you didn't say what the failure phrases are, the best I can do is give examples but you should be able to fill in the details.

LightBulb
All scripts untested unless otherwise noted

Apprentice Joined: 19 Jan 2002 Posts: 107

well,actually i didnt send thoose messages because i didnt want to make u work so mucth and make all my tigger,i wanted to try to get it... but if u want to help me so much it is ok by me ^^ so thanks again,and here there are the failure phrases:

Un picor en la nariz te impide mantener la concentracion.
Algo te distrae y pierdes la concentracion.
Has tenido una laguna mental mientras invocabas el hechizo.
Has perdido la concentracion.
Pierdes la concentracion.
Has tenido una laguna mental mientras invocabas el hechizo.
Has fallado.
Algo en tu garganta impide que recites bien la frase.

and if i cast well thoose three spells :

escudo hielo :
Un torbellino de granizo te envuelve protectivamente.

vigor:
Sientes un vigor bestial consumirte...

piel petrea:
Tu piel se vuelve dura como la piedra, aunque flexible.

but there is another fact,on the two words spells,i must put 'SPELL' if not,it doesnt work

Well,thank once more... Articnal

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

I wasn't asking for those phrases, I'm all in favor of people writing their own scripts. But since you did, I'll do my best. Since I still don't have the actual "cast" command (this is clearly not an English-language mud, so I can't assume it's "cast") you may still need to modify things. All I did was cut-and-paste the failure/success phrases into the appropriate triggers and put the correct (I hope) values into the @spell variable and the cast commands.

#AL spellup {#T+ Spellup;#VAR spell {SPELL escudo hielo};cast SPELL escudo hielo}

#CLASS Spellup
#TR {Un picor en la nariz te impide mantener la concentracion} {cast @spell}
#TR {Algo te distrae y pierdes la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has perdido la concentracion} {cast @spell}
#TR {Pierdes la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has fallado} {cast @spell}
#TR {Algo en tu garganta impide que recites bien la frase} {cast @spell}

#TR {Un torbellino de granizo te envuelve protectivamente} {#VAR spell vigor;cast vigor}
#TR {Sientes un vigor bestial consumirte} {#VAR spell {SPELL piel petria};cast SPELL piel petria}
#TR {Tu piel se vuelve dura como la piedra, aunque flexible} {#ECHO Spellup finished!;#T- Spellup}
#TR {out of mana message} {#ECHO Spellup aborted, OUT OF MANA!!;#T- Spellup}
#CLASS 0

The concept is to write a trigger for each failure phrase with the command to repeat the spell and to write a trigger for each success phrase with the commands to update the @spell variable and cast the next spell, and an alias to start everything.

Some people will prefer to use a button instead of the alias, others may prefer a macro, and some might prefer to put it in a speed menu. I prefer keyboard entry, so I use aliases but they can be easily converted to any of the other methods.

LightBulb
All scripts untested unless otherwise noted

Apprentice Joined: 19 Jan 2002 Posts: 107

Well,i have changed it,and there are still three problems (i had to put a few @ which where missing)

#AL spellup {#T+ Spellup;#VAR spell {'escudo hielo'};cast @SPELL}

#CLASS Spellup
#TR {Un picor en la nariz te impide mantener la concentracion} {cast @spell}
#TR {Algo te distrae y pierdes la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has perdido la concentracion} {cast @spell}
#TR {Pierdes la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has fallado} {cast @spell}
#TR {Algo en tu garganta impide que recites bien la frase} {cast @spell}

#TR {Un torbellino de granizo te envuelve protectivamente} {#VAR spell {vigor};cast @spell }
#TR {Sientes un vigor bestial consumirte} {#VAR spell {'piel petrea'};cast @spell}
#TR {Tu piel se vuelve dura como la piedra, aunque flexible} {#ECHO Spellup finished!;#T- Spellup}
#TR {No tienes suficiente mana} {#ECHO Spellup aborted, OUT OF MANA!!;#T- Spellup}
#CLASS 0

well,when putting it in the imput line and pressing intro,it seems to acept all the lines but the next two:

#CLASS Spellup
#TR {Un torbellino de granizo te envuelve protectivamente} {#VAR spell {vigor};cast @spell }

if i insert the second one without the rest,zmud admits it,so there is still a problem, the tigger doesnt switchs of when finishes,so when ever it sees a failure spell line,it starts again
well,its almost done,and i think the fail must be on the class line. Thanks re-again for ur help.
Oh,another think,this mud works with the word cast (english) instead of conjurar (spanish) so i would keep working with the word cast

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

I misunderstood your statement about putting 'SPELL' for multiword spells, sorry. However, I didn't leave out any @ that I can see. I deliberately used the actual command instead of the variable in the alias and the triggers which changed the variable.

The problem appears to be that you attempted to cut-and-paste the entire script as a single block instead of line-by-line, and the blank lines caused the two commands following them to be ignored. The first one to be ignored was the #CLASS Spellup command, so all the triggers went into the None class. Create a Spellup class and move the triggers into it. Testing reveals two triggers which fire on the same phrase, "Algo te distrae y pierdes la concentracion", so I eliminated the longer trigger. Here's the final, TESTED version. I eliminated the blank lines, so if you want, you can delete the previous script and then cut-and-paste as is. Change the final trigger to something meaningful, I'm sure your MUD won't ever send "out of mana message".

#AL spellup {#T+ Spellup;#VAR spell {'escudo hielo'};cast 'escudo hielo'}
#CLASS Spellup
#TR {Un picor en la nariz te impide mantener la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has perdido la concentracion} {cast @spell}
#TR {Pierdes la concentracion} {cast @spell}
#TR {Has tenido una laguna mental mientras invocabas el hechizo} {cast @spell}
#TR {Has fallado} {cast @spell}
#TR {Algo en tu garganta impide que recites bien la frase} {cast @spell}
#TR {Un torbellino de granizo te envuelve protectivamente} {#VAR spell vigor;cast vigor}
#TR {Sientes un vigor bestial consumirte} {#VAR spell {'piel petria'};cast 'piel petria'}
#TR {Tu piel se vuelve dura como la piedra, aunque flexible} {#ECHO Spellup finished!;#T- Spellup}
#TR {out of mana message} {#ECHO Spellup aborted, OUT OF MANA!!;#T- Spellup}
#CLASS 0

LightBulb
All scripts untested unless otherwise noted

Apprentice Joined: 19 Jan 2002 Posts: 107

Well tnx a lot for all ur help lightbulb,and thanks to u now i know how to use variables and classes properly... =)

Tnx again

Articnal