jessew
Apprentice
Joined: 03 Mar 2003
Posts: 141
|
 Posted: Wed Dec 08, 2004 5:47 am
Medieiva - Updated Backstab/Mal Reporter
|
To Install - use the #read command, if you dont know how the easiest way is to copy these scripts and save them to a file, put it in your zmud root directory and type #read <filename>
You will need my CaebUtils script installed before installing this one, its posted in the finished script forums.
http://forums.zuggsoft.com/phpbb/viewtopic.php?t=19482
And here's the backstab reporter , I made it so you could add weapon procs, I only added the trigger for my dagger but its fairly easy to add your own. Just put a trigger for your proc in the "CaebBackstab|Triggers|BackstabInformation" class then in the command part of the trigger call the cb_addproc alias with whatever text you want to represent your proc. e.g. For my neumanga blade I did this
| Code: |
| #TRIG {A searing wave*blade and scorches} {cb_addproc @CC(bold,white)HOLY} |
Remember to install the above script first it needs the prompt script from that and the themer.
Edit Fixed Enemy mals being misreported.
| Code: |
;;v2.5.1 12/9/04
;; -Fixed Misreporting when dieing to malediction
#IF (@CaebUtils_Version < 1.1) {
#MESSAGE CaebBackstab Requires CaebUtils script to be installed first.
#ABORT 1
}
#DELCLASS "CaebBs"
#DELCLASS "CaebBackstab"
#CLASS "CaebBackstab"
#VAR CaebBackstab_Version 2.5
;;Main alias to check for report now
#ALIAS cbscheckreport {
#IF (@cb_malreport) {
#IF (!@cb_enemycond & (@cb_malreport < 2)) {
#VAR cb_malreport %eval(@cb_malreport + 1) 0 "CaebBackstab"
} {
cb_domalreport
}
}
#IF (@cb_bsreport) {cb_dobsreport}
}
;;Switch from show to show/chat
#VAR cb_option_show 1 _nodef "CaebBackstab"
#ALIAS cbshow {
#VAR cb_option_show %bitxor(@cb_option_show,1) _nodef "CaebBackstab"
cmsg "CaebBackStab" "Now reporting to %if(@cb_option_show,show,chat)." "%if(@cb_option_show,show,chat)"
}
;;Turn script off/on
#ALIAS cbtoggle {
#IF (%class("CaebBackstab|Triggers|Starters")) {
#T- "CaebBackstab|Triggers|Starters"
cpremoveaction cbscheckreport
cmsg "CaebBackstab" "Backstab/Mal reporting has been turned off." "off"
} {
#T+ "CaebBackstab|Triggers|Starters"
cpaddaction cbscheckreport
cmsg "CaebBackstab" "Backstab/Mal reporting has been turned on." "on"
}
}
;;Lets hook script up to themer
#ALIAS cbcolor {cthchange %1 %2 cb_theme1 cb_theme cbtheme "CaebBackstab"}
#ALIAS cbtheme {cthshow "Caebryn's BackStab and Mal Reporter" cb_theme1 cb_example cb_explain cbcolor}
#VAR cb_theme1 {8|4|14|11|15|12}
#VAR cb_theme {@CC(bold,black)|@CC(red)|@CC(bold,yellow)|@CC(bold,cyan)|@CC(bold,white)|@CC(bold,red)}
#VAR cb_explain {"Skeleton Words"|"Seperators"|"Multipliers and Shield Damage"|"Enemy Name and Condition"|"Current Hps"|"The T Twist Marker"}
#FUN cb_example {@cb_theme.1"You just "@cb_theme.2"|"@cb_theme.3"5.0"@cb_theme.2"| "@cb_theme.1"on "@cb_theme.4"Vryce "@cb_theme.1"to "@cb_theme.4"Gaping "@cb_theme.2"| "@CC(bold,red)"FireShield "@cb_theme.3"-100 "@cb_theme.2"| "@cb_theme.5"500"@cb_theme.2"-"@CC(bold,red)"CPK"@cb_theme.2"|"}
;;Resets all variables in the script to default.
#ALIAS cb_reset {
#VAR cb_mymort 0 0 "CaebBackstab"
#VAR cb_malreport 0 0 "CaebBackstab"
#VAR cb_bsreport 0 0 "CaebBackstab"
#VAR cb_malpower 0 0 "CaebBackstab"
#VAR cb_enemycond 0 0 "CaebBackstab"
#VAR cb_enemyname 0 0 "CaebBackstab"
#VAR cb_mydeath 0 0 "CaebBackstab"
#VAR cb_attempt 0 0 "CaebBackstab"
#VAR cb_bslist "" "" "CaebBackstab"
#VAR cb_twists "" "" "CaebBackstab"
#VAR cb_procs "NONE|NONE|NONE" "NONE|NONE|NONE" "CaebBackstab"
#VAR cb_fireshield 0 0 "CaebBackstab"
#VAR cb_iceshield 0 0 "CaebBackstab"
}
;;Script Commands
#ALIAS cb_addusermal {
#VAR cb_malpower @cpmana 0 "CaebBackstab"
#VAR cb_malreport 1 0 "CaebBackstab"
#VAR cb_enemyname %1 0 "CaebBackstab"
cb_enabletriggers
}
#ALIAS cb_addenemymal {
#VAR cb_malreport 3 0 "CaebBackstab"
#VAR cb_enemyname %1 0 "CaebBackstab"
#VAR cb_mydeath %2 0 "CaebBackstab"
cb_enabletriggers
}
#ALIAS cb_adduserbackstab {
#VAR cb_bsreport 1 0 "CaebBackstab"
#VAR cb_enemyname %1 0 "CaebBackstab"
#VAR cb_bslist %additem("%2",@cb_bslist) "" "CaebBackstab"
#VAR cb_attempt %eval(@cb_attempt + 1) 0 "CaebBackstab"
cb_enabletriggers
}
#ALIAS cb_addenemybackstab {
#VAR cb_bsreport 2 0 "CaebBackstab"
#VAR cb_enemyname %1 0 "CaebBackstab"
#VAR cb_bslist %additem("%2",@cb_bslist) "" "CaebBackstab"
#VAR cb_attempt %eval(@cb_attempt + 1) 0 "CaebBackstab"
cb_enabletriggers
}
#ALIAS cb_dobsreport {
cb_disabletriggers
#CASE @cb_bsreport {cb_douserbackstab} {cb_doenemybackstab}
cb_reset
}
#ALIAS cb_domalreport {
cb_disabletriggers
#IF (!@cb_enemycond) {
cb_setenemycond "Unknown"
}
#IF (@cb_malreport = 3) {
cb_doenemymal
} {
cb_dousermal
}
cb_reset
}
#ALIAS cb_setenemycond {#VAR cb_enemycond %1 "" "CaebBackstab"}
#ALIAS cb_addtwist {#VAR cb_twists %additem(@cb_attempt,@cb_twists) "" "CaebBackstab"}
#ALIAS cb_setfireshield {#VAR cb_fireshield 1 0 "CaebBackstab"}
#ALIAS cb_seticeshield {#VAR cb_iceshield 1 0 "CaebBackstab"}
#ALIAS cb_setmymort {#VAR cb_mymort 1 0 "CaebBackstab"}
#ALIAS cb_addproc {
#VAR cb_procs {%replaceitem("%1",@cb_attempt,@cb_procs)} "NONE|NONE|NONE" "CaebBackstab"
}
#ALIAS cb_enabletriggers {
#T+ "CaebBackstab|Triggers|BackstabInformation"
}
#ALIAS cb_disabletriggers {
#T- "CaebBackstab|Triggers|BackstabInformation"
}
;;Display Functions
#FUN cbf_enemydamage {%if(@cbf_damage,%concat(@cb_theme.1," for ",@cb_theme.3,%abs(@cbf_damage),@cb_theme.1,"dmg"))}
#FUN cbf_damage {%eval(@cpoldhp - @cphp)}
#FUN cbf_fireshield {%if(@cb_fireshield,%concat(@CC(bold,red),"FireShield ",@cb_theme.3,@cbf_damage,@cb_theme.2," | "))}
#FUN cbf_iceshield {%if(@cb_iceshield,%concat(@CC(bold,cyan),"IceShield ",@cb_theme.3,@cbf_damage,@cb_theme.2," | "))}
#FUN cbf_enemyname {%concat(@cb_theme.4, %proper(@cb_enemyname))}
#FUN cbf_enemycond {%if(@cb_enemycond,%concat(@cb_theme.1," to ",@cb_theme.4,@cb_enemycond))}
#FUN cbf_multipliers {%concat(@cb_theme.2,"|",%replace(%exec("#LOOP 1,%numitems(@cb_bslist) {@cbf_multiplier(%i)}"),"|",%concat(@cb_theme.2,"|")),@cb_theme.2,"|")}
#FUN cbf_multiplier {%concat(@cb_theme.3,%item(@cb_bslist,%1),%if(%ismember(%1,@cb_twists),%concat(@cb_theme.6,"T")),%if(%item(@cb_procs,%1)!= "NONE",%concat("|",%item(@cb_procs,%1))))}
#FUN cbf_malpower {%concat(@cb_theme.2,"| ",@cb_theme.3,@cb_malpower,"m Mal",@cb_theme.2," |")}
#FUN cbf_malenemy {%concat(@cb_theme.2,"| ",@cb_theme.3,"MalEdICteD",@cb_theme.2," |")}
#ALIAS cb_douserbackstab {
#EXEC {%concat(%if(@cb_option_show,"#SHOW %item(@cb_theme,1)You Just ","#EMOTEALL %item(@cb_theme,1)just")," @cbf_multipliers %concat(@cb_theme.1,"on ")@cbf_enemyname@cbf_enemycond@cb_theme.2 | @cbf_iceshield@cbf_fireshield@cb_theme.5%if(@cb_mymort,@CC(bold,red)MoRtEd,@cphp)@cb_theme.2-@cb_theme.5@colorpk@cb_theme.2 |")}
}
#ALIAS cb_doenemybackstab {
#EXEC {%concat(%if(@cb_option_show,"#SHOW ","#EMOTEALL %item(@cb_theme,2)| "),"@cbf_enemyname@cb_theme.1 just @cbf_multipliers%concat(@cb_theme.1," on ",@cb_theme.4,"Me")@cbf_enemydamage@cb_theme.2 | @cb_theme.5@cphp@cb_theme.2-@cb_theme.5@colorpk@cb_theme.2 |")}
}
#ALIAS cb_dousermal {
#EXEC {%concat(%if(@cb_option_show,"#SHOW %item(@cb_theme,1)You just ","#EMOTEALL %item(@cb_theme,1)just")," @cbf_malpower %concat(@cb_theme.1,"on ")@cbf_enemyname@cbf_enemycond@cb_theme.2 | @cbf_iceshield@cbf_fireshield@cb_theme.5@cphp@cb_theme.2-@cb_theme.5@colorpk@cb_theme.2 |")}
}
#ALIAS cb_doenemymal {
#EXEC {%concat(%if(@cb_option_show,"#SHOW ","#EMOTEALL %item(@cb_theme,2)| "),"@cbf_enemyname@cb_theme.1 just @cbf_malenemy %concat(@cb_theme.4,"Me",%if(@cb_mydeath,%item(@cb_theme,6) Dead))@cbf_enemydamage@cb_theme.2 | @cb_theme.5@cphp@cb_theme.2-@cb_theme.5@colorpk@cb_theme.2 |")}
}
;;Test Aliases
#ALIAS cbsetupfake {
#VAR cb_malpower 1400 0 "CaebBackstab"
#VAR cb_fireshield 1 0 "CaebBackstab"
#VAR cb_iceshield 1 0 "CaebBackstab"
#VAR cphp 1000 NA "CaebUtils|CaebPrompt"
#VAR cphpold 1500 NA "CaebUtils|CaebPrompt"
#VAR cbpktemp @cpdpk "" "CaebBackstab"
#VAR cpdpk CPK LPK "CaebUtils|CaebPkDetect"
cb_setenemycond "Gaping"
cb_setmymort 1
#VAR cb_procs "NONE|@CC(bold,white)HOLY|NONE"
#VAR cb_enemyname "Vryce" 0 "CaebBackstab"
#VAR cb_attempt 3 0 "CaebBackstab"
#VAR cb_bslist "5.5|5.0|WHF" "" "CaebBackstab"
#VAR cb_twists "1" "" "CaebBackstab"
}
#ALIAS cbshowfakeuserstab {
cbsetupfake
cb_douserbackstab
#VAR cpdpk @cbpktemp LPK "CaebUtils|CaebPkDetect"
cb_reset
}
#ALIAS cbshowfakeenemystab {
cbsetupfake
cb_doenemybackstab
#VAR cpdpk @cbpktemp LPK "CaebUtils|CaebPkDetect"
cb_reset
}
#ALIAS cbshowfakeusermal {
cbsetupfake
cb_dousermal
#VAR cpdpk @cbpktemp LPK "CaebUtils|CaebPkDetect"
cb_reset
}
#ALIAS cbshowfakeenemymal {
cbsetupfake
cb_doenemymal
#VAR cpdpk @cbpktemp LPK "CaebUtils|CaebPkDetect"
cb_reset
}
#CLASS 0
;;These triggers are always on while backstab/mal reporting is enabled
#CLASS "CaebBackstab|Triggers|Starters"
#TRIG {^(*) turns * head, noticing you.$} {cb_adduserbackstab "%1" FF}
#TRIG {^You lunge at (*) with * but miss.$} {cb_adduserbackstab "%1" FF}
#TRIG {^With unbelievable luck, (*) moves*you*$} {cb_adduserbackstab "%1" FF}
#TRIG {^Your *barely hurts (*) at all.$} {cb_adduserbackstab "%1" 1.5}
#TRIG {^Your*tip*finds (*)'s shoulder blades.$} {cb_adduserbackstab "%1" 2.0}
#TRIG {^*stab (*) in the back, but your *$} {cb_adduserbackstab "%1" 2.5}
#TRIG {^* off-target as you stab at (*)'s back.$} {cb_adduserbackstab "%1" 3.0}
#TRIG {^You plunge * into the back of (*).$} {cb_adduserbackstab "%1" 3.5}
#TRIG {^(*) convulses in pain as you land*$} {cb_adduserbackstab "%1" 4.0}
#TRIG {^*through (*)'s defenses and *$} {cb_adduserbackstab "%1" 4.5}
#TRIG {^* finds a chink in (*)'s *$} {cb_adduserbackstab "%1" 5.0}
#TRIG {^* true mark as you stab at (*)'s*$} {cb_adduserbackstab "%1" 5.5}
#TRIG {^(*) makes a strange sound but is*you*$} {cb_adduserbackstab "%1" ICE}
#TRIG {^*turning your head, you notice (*).$} {cb_addenemybackstab "%1" FF}
#TRIG {^*avoid (*) as he lunges at your back.} {cb_addenemybackstab "%1" FF}
#TRIG {^You wince in pain as (*) clumsily*$} {cb_addenemybackstab "%1" 1.5}
#TRIG {^*pain as (*) stabs at your shoulder*$} {cb_addenemybackstab "%1" 2.0}
#TRIG {^You reel in pain as (*) lunges*$} {cb_addenemybackstab "%1" 2.5}
#TRIG {^*back as (*) stabs at your back with*$} {cb_addenemybackstab "%1" 3.0}
#TRIG {^A vicious backstab from (*) causes*$} {cb_addenemybackstab "%1" 3.5}
#TRIG {^*pain as (*) powerfully stabs you*$} {cb_addenemybackstab "%1" 4.0}
#TRIG {^(*) skillfully stabs at your back*$} {cb_addenemybackstab "%1" 4.5}
#TRIG {^*your back as (*) stabs at you with*$} {cb_addenemybackstab "%1" 5.0}
#TRIG {^(*) critically stabs you in the back*$} {cb_addenemybackstab "%1" 5.5}
#TRIG {^(*) stabs you in the back critically*$} {cb_addenemybackstab "%1" 5.5}
#TRIG {^Suddenly (*) stabs you in the back*$} {cb_addenemybackstab "%1" ICE}
#TRIG {You raise your hands, and your aura engulfs (*).} {cb_addusermal "%1"}
#TRIG {You focus and send a deadly blast of power at (*).} {cb_addusermal "%1"}
#TRIG {^(*) raises * hands and strikes you with a burst of power.} {cb_addenemymal "%1" 0}
#TRIG {^(*) smiles triumphantly as the lethal bolt of magic dissolves you.} {cb_addenemymal "%1" 1}
#CLASS 0
#CLASS "CaebBackstab|Triggers|BackstabInformation" disable
#TRIG {^*is DEAD} {cb_setenemycond "Iced!"}
#TRIG {^*is*and will die soon, i*t aided.} {cb_setenemycond "Mortally Wounded"}
#TRIG {^*barely clings to life.} {cb_setenemycond "Clinging"}
#TRIG {^*pales visibly as death nears.} {cb_setenemycond "Paling"}
#TRIG {^*with blood from oozing wounds.} {cb_setenemycond "Oozing"}
#TRIG {^*has many grievous wounds.} {cb_setenemycond "Grievous"}
#TRIG {^*looks pretty awful.} {cb_setenemycond "Pretty Awful"}
#TRIG {^*has some large, gaping wounds.} {cb_setenemycond "Gaping"}
#TRIG {^*nasty wounds and bleeding cuts.} {cb_setenemycond "Nasty Wounds"}
#TRIG {^*grimaces with pain.} {cb_setenemycond "Grimacing"}
#TRIG {^*has quite a few wounds.} {cb_setenemycond "Quite a Few Wounds"}
#TRIG {^*winces in pain.} {cb_setenemycond "Wincing"}
#TRIG {^*has some minor wounds.} {cb_setenemycond "Minor Wounds"}
#TRIG {^*has some small wounds and bruises.} {cb_setenemycond "Small Wounds"}
#TRIG {^*looking welt on the forehead.} {cb_setenemycond "Nasty Welt"}
#TRIG {^*has a few scratches.} {cb_setenemycond "Scratches"}
#TRIG {^*is in excellent condition.} {cb_setenemycond "Excellent"}
#TRIG {You are mortally wounded} {cb_setmymort 1}
#TRIG {You twist * as you remove it from (*)'s back.} {cb_addtwist}
#TRIG {(*) twists * as * removes it from your back.} {cb_addtwist}
#TRIG {^Energy rebounds from *'s fireshield hitting you.$} {cb_setfireshield}
#TRIG {^Shards of ice fly from *'s iceshield, striking you.$} {cb_seticeshield}
#TRIG {A searing wave*blade and scorches} {cb_addproc @CC(bold,white)HOLY}
#TRIG {plunge*poisoning} {cb_addproc @CC(white)POISON}
#TRIG {A tongue of flame erupts} {cb_addproc @CC(bold,red)FIRE}
#CLASS 0
#CLASS "CaebBackstab|Help"
#ALIAS bshelp {
#SHOW @bshelpmsg
}
#ALIAS bshelpcreate {
#VAR bshelpmsg @hhtitle(%concat("CaebBackstab v",@CaebBackstab_Version," Help file")) _nodef "CaebBackstab|Help"
#VAR bshelpmsg %concat(@bshelpmsg,@hhline) _nodef "CaebBackstab|Help"
#VAR bshelpmsg %concat(@bshelpmsg,@hhentry(bshelp,"-","Show this help file.") _nodef "CaebBackstab|Help"
#VAR bshelpmsg %concat(@bshelpmsg,@hhentry(cbshow,"-","Toggle reporting from show and chat.") _nodef "CaebBackstab|Help"
#VAR bshelpmsg %concat(@bshelpmsg,@hhentry(cbtoggle,"-","Toggle reporting on and off.") _nodef "CaebBackstab|Help"
#VAR bshelpmsg %concat(@bshelpmsg,@hhline) _nodef "CaebBackstab|Help"
}
#CLASS 0
#T- "CaebBackstab|Triggers|BackstabInformation"
#T- "CaebBackstab|Triggers|Starters"
bshelpcreate
cbtoggle
cb_reset
#IF (!%yesno("Would you like to add a submenu to your speedmenu for this script?")) {
cmsg "CaebBackstab" "Not installing menu please type bshelp to see commands." "bshelp"
#ABORT 1
}
#CLASS "CaebBackstab|Menu"
#MENU {Caebryn's Backstab Reporter} {} "" "CaebBackstabSubMenu"
#CLASS 0
#CLASS "CaebBackstab|Menu|CaebBackstabSubMenu" menu
#MENU {HelpFile} {bshelp}
#MENU {Switch reporting to %if(@cb_option_show,"Chat","Show")} {cbshow}
#MENU {Turn Backstab Reporter %if(%trigger("CaebBackstab|Triggers|Starters"),Off,On)} {cbtoggle}
#CLASS 0
|
|
|
