check_1:


if_1 goto check_hands //this means if there is a %1, goto the label check_hands


echo What do you want to skin? //else, echo something and then exit


exit





check_hands:


match longsword longsword in your right hand //sets up a trigger for 'Longsword in your right hand' and when it is triggered it goes to the label longsword


match waraxe waraxe in your right hand


match handaxe handaxe in your right hand


match get_knife You glance down to see


put glance //put = send to mud. Glance tells you what you are holding in your hands.


matchwait //basicaly stops the script here, it can only advance if one of the matches are matched.





	longsword:


	setvariable weapon_temp longsword //setvariable <variable name> <value>


	put put my longsword in my %sheath


	goto get_knife


	


	waraxe:


	setvariable weapon_temp waraxe


	put put my waraxe in my %sheath


	goto get_knife


	


	handaxe:


	setvariable weapon_temp handaxe


	put put my handaxe in my %sheath


	goto get_knife





get_knife:


match skin You remove


match error I could not find what you were referring to.


put get %skinning_knife from my %skinning_knife_holder


matchwait





skin:


match success You skinned


match fail You botched the job.


match fail You can only skin creatures!


put kneel


put skin %1 //skins the <creature>


matchwait





success:


counter set %skin_success //the counter (%c) variable is a special variable and the only one you can do math on. This sets the counter to what the %skin_success variable is.


counter add  //and then increments it


setvariable skin_success %c //and then saves it back to the skin_success variable


save success //saves the string 'success' to the temporary variable %s


goto stand





fail:


counter set %skin_fail


counter add


setvariable skin_fail %c


save fail


goto stand





stand:


match stand_ok You are already


match stand_ok You stand back up.


match stand_again You struggle


put stand


matchwait





stand_again:


pause


goto stand





stand_ok:


goto cleanup





cleanup:


put put my %skinning_knife in my %skinning_knife_holder


waitfor You put


if_2 goto %s%_finish


goto fail_finish





success_finish:


put get %2


put open my %loot_container


put put my %2 in my %loot_container


waitfor Ok, it opened. //waitfor pauses the script untill it it matches the text following it


waitfor You put


put close my %loot_container


put search %1


put get my %weapon_temp


deletevariable weapon_temp


exit





fail_finish:


put search %1


put get my %weapon_temp


deletevariable weapon_temp


exit





error:


echo ** Skinning knife could not be found! **


exit