Talmark
Novice
Joined: 22 Nov 2003
Posts: 34
|
 Posted: Mon Oct 04, 2004 8:36 pm
Genesis Vitals Gauges
|
This script simply keeps track of all of your vitals.
It updates each time you type h or v.
It will display six gauges at the top of your mud window:
Alignment, Progress, Health, Mana, Encumbrance, and Fatigue.
If you want it to play a sound when you start to get hurt,
simply put the sound you want to here in the sounds file:
Zmud\Genesis\Sounds. Name the one you want to hear when you're
starting to get hurt Ouch.wav and the one you want to hear when
you're seriously hurt Pain.wav.
It also grabs all of your other vitals
(panic, thirst, hunger, intoxication), but doesn't
display a guage for them. You should be able to easily
customize this to display as much or as little info as you
like in the form of gauges.
This should work for other LP muds as well, I think.
| Code: |
#CLASS {Vitals}
#TRIGGER {^{> |}You are (*).$} {
#IF {%ismember( %1, @encumbrance)} {#MATH encumbrance_num (%ismember( %1, @encumbrance))-1}
#IF {%ismember( %1, @alignlevels)} {#VAR alignment %ismember( %1, @alignlevels)}
#IF {%ismember( %1, @intoxication)} {#MATH intox (%ismember( %1, @intoxication)-1)}
}
#CLASS 0
#CLASS {Vitals|Panic-Fatigue}
#VAR fatigue_num {0}
#VAR fatigue {extremely alert|very alert|alert|somewhat alert|slightly alert|slightly weary|somewhat weary|weary|very weary|extremely weary|slightly tired|somewhat tired|tired|very tired|extremely tired|slightly exhausted|somewhat exhausted|exhausted|very exhausted|extremely exhausted}
#VAR panic {extremely secure|very secure|secure|somewhat secure|slightly secure|extremely calm|very calm|calm|somewhat calm|slightly calm|slightly uneasy|somewhat uneasy|uneasy|very uneasy|extremely uneasy|slightly worried|somewhat worried|worried|very worried|extremely worried|slightly panicky|somewhat panicky|panicky|very panicky|extremely panicky}
#VAR panic_level {0}
#TRIGGER {^{> |}You feel (*) and (*).$} {
#IF {%ismember( %1, @panic)} {#MATH panic_level (%ismember( %1, @panic)-1)}
#IF {%ismember( %2, @fatigue)} {#MATH fatigue_num (%ismember( %2, @fatigue)-1)}
}
#BUTTON 2 {FATIGUE} {} {} {} {@fatigue_num} {} {} {} {} {} {} {} {} {32832} {} {Gauge||6|19|15|7} {} "" {Explore|Inset|Right} {} {}
#CLASS 0
#CLASS {Vitals|Health-Mana}
#VAR health_num {9}
#VAR health {at death's door|barely alive|terribly hurt|in a very bad shape|in a bad shape|very hurt|feeling rather hurt|hurt|somewhat hurt|slightly hurt|feeling very well}
#VAR mana_num {10}
#VAR mana {in a vegetable state|exhausted|worn down|indisposed|in a bad shape|very degraded|rather degraded|degraded|somewhat degraded|slightly degraded|in full vigour}
#TRIGGER {^{> |}{You|He|She|It} {are|is|seems to be} {@health}.$} {#CO pink}
#TRIGGER {^{> |}You are physically (*) and mentally (*).$} {
#IF {%ismember( %1, @health)} {
#CO yellow
#VAR health_num %ismember( %1, @health)
}
#IF {%ismember( %1, @health) = 1 OR %ismember( %1, @health) = 2} {#PL Pain.wav}
#IF {%ismember( %1, @health) = 3 OR %ismember( %1, @health) = 4 OR %ismember( %1, @health) = 5} {#PL Ouch.wav}
#IF {%ismember( %2, @mana)} {#MATH mana_num (%ismember( %2, @mana))-1}
}
#TRIGGER {^{> |}The * is {@health}.} {#CO pink}
#BUTTON 1 {HEALTH} {} {} {} {@health_num} {} {} {} {} {} {} {} {} {32} {} {Gauge||12|11|4|7} {} "" {Explore|Inset|Right} {} {}
#BUTTON 5 {MANA} {} {} {} {@mana_num} {} {} {} {} {} {} {} {} {48} {} {Gauge||12|10|5|7} {} "" {Explore|Inset|Stack|Right} {} {} {2}
#CLASS 0
#CLASS {Vitals|Encumbrance}
#VAR encumbrance_num {3}
#VAR encumbrance {unencumbered|lightly burdened|burdened|encumbered|heavily loaded|over taxed|collapsing under your load}
#BUTTON 3 {ENCUMBRANCE} {} {} {} {@encumbrance_num} {} {} {} {} {} {} {} {} {32832} {} {Gauge||8|6|5|7} {} "" {Explore|Inset|Right} {} {} {2}
#CLASS 0
#CLASS {Vitals|Alignment}
#VAR alignment {23}
#VAR alignlevels {damned|demonic|beastly|malevolent|evil|foul|nasty|wicked|sinister|unsympathetic|untrustworthy|disagreeable|neutral|agreeable|trustworthy|sympathetic|nice|sweet|good|devout|blessed|saintly|holy}
#BUTTON 4 {%upper( %item( @alignlevels, @alignment))} {} {} {} {@alignment-1} {} {} {} {} {} {} {} {} {32880} {} {Gauge||12|22|13|7} {} "" {Explore|Inset} {} {}
#CLASS 0
#CLASS {Vitals|Intox}
#VAR intoxication {sober|slightly tipsy|somewhat tipsy|tipsy|very tipsy|extremely tipsy|slightly intoxicated|somewhat intoxicated|intoxicated|very intoxicated|extremely intoxicated|slightly drunk|somewhat drunk|drunk|very drunk|extremely drunk|slightly tanked|somewhat tanked|tanked|very tanked|extremely tanked|slightly blitzed|somewhat blitzed|blitzed|very blitzed|extremely blitzed|slightly wasted|somewhat wasted|wasted|very wasted|extremely wasted|slightly toasted|somewhat toasted|toasted|very toasted|extremely toasted|slightly pissed|somewhat pissed|pissed|very pissed|extremely pissed|slightly stoned|somewhat stoned|stoned|very stoned|extremely stoned|slightly obliviated|somewhat obliviated|obliviated|very obliviated|extremely obliviated}
#VAR intox {0}
#CLASS 0
#CLASS {Vitals|Hunger-Thirst}
#VAR Hunger {barely eat more|eat a little more|eat some more|eat a lot more|eat quite a lot more}
#VAR Thirst {barely drink more|drink a little more|drink some more|drink a lot more|drink quite a lot more}
#VAR hunger_level {0}
#VAR thirst_level {1}
#TRIGGER {^{> |}You can (*) and (*).$} {
#MATH hunger_level {%ismember( %1, @hunger)-1}
#MATH thirst_level {%ismember( %2, @thirst)-1}
}
#CLASS 0
|
|
|
