Zugg Software :: View topic

Beginner Joined: 07 Dec 2001 Posts: 21

PKing in this Mud can get a bit hectic and complicated so I wanted to make triggers to heal afflictions once I get them. Now I can make simple triggers to eat this or drink that to heal, but the thing is eating, drinking and applying each has its own little timer, where I can't do that action again or it won't take have any effect. There are classes that can inflict two afflictions at once so the simple tiggers won't work.

Basicly how it looks like is this...

You feel light headed and dizzy.
Outb ginseng
Eat ginseng
(Message saying you healed the affliction)
(2-3 seconds later)
You may eat another plant.

Your right arm breaks from all the damage
Apply mending
(Message saying you healed the affliction)
(2-3 seconds later)
You may apply another salve to yourself.

You begin feeling slightly flushed
Drink immunity
(Message saying you healed the affliction)
(2-3 seconds later)
You may drink another affliction-healing elixir.

How would I go about making a trigger to cure multiple afflictions say if I were hit with two afflictions where I need to eat herbs to cure, salves, elixers?

And is there a way to stop others from activating the trigger simply by saying the line used to activate the trigger?

MASTER Joined: 28 Nov 2000 Posts: 4817 Location: USA

You will probably need to establish several flag variables which can be set to 1 when it's okay to eat a herb, apply a salve, or drink an elixir and set to 0 when it's not. Your triggers can then check the flag variable to see if the appropriate action is available. If it is, then you can act immediately. If not, you'll need to establish a stringlist variable for that action where you can queue up the appropriate remedies until you are able to implement them.

Achaea and it's look-alikes are popular and many people have tried to solve this problem. You can probably find some excellent approaches already scripted by doing a search through the forum for keywords such as queue, herb, balance, etc.

LightBulb
All scripts untested unless otherwise noted

Beginner Joined: 07 Dec 2001 Posts: 21

I searched through the past posts, but I couldn't find one that was what I wanted, though one was very close..it just confused the heck out of me. Though that post did bring up a few things I didn't think of.

Theres also three states, anorexia, and slickness where you can't eat or apply salves.

I'm more or less just lost to this all, so if someone can help me out, and maybe explain how this works, I'll really appreciate it. Till then I'll take another look through the older posts.

GURU Joined: 10 Oct 2000 Posts: 4379 Location: USA

Try using this script:
#ALARM "eatalarm" {*1} {#IF ((@eat) and !(%item(@eatqueue, 1) != "")) {#VAR eat 0;eat %item(@eatqueue, 1);#VAR eatqueue %delitem(%item(@eatqueue, 1), @eatqueue)}}
#ALARM "drinkalarm" {*1} {#IF ((@drink) and !(%item(@drinkqueue, 1) != "")) {#VAR drink 0;drink %item(@drinkqueue, 1);#VAR drinkqueue %delitem(%item(@drinkqueue, 1), @drinkqueue)}}
#ALARM "applyalarm" {*1} {#IF ((@apply) and !(%item(@applyqueue, 1) != "")) {#VAR apply 0;apply %item(@applyqueue, 1);#VAR applyqueue %delitem(%item(@applyqueue, 1), @applyqueue)}}
#TRIGGER {You may eat another plant.} {#VAR eat 1}
#TRIGGER {You may apply another salve to yourself.} {#VAR apply 1}
#TRIGGER {You may drink another affliction-healing elixir.} {#VAR drink 1}

Now, you just need to create a trigger for every affliction that you want to cure and each trigger will add the item to drink/apply/eat to the corresponding queue. You need to make sure to use %additem to add it to the list in order to allow duplicates and also to get the item out of the bag so it is available to eat/drink/apply. Here is an example trigger:
#TRIGGER {You feel light headed and dizzy.} {Outb ginseng;#VAR eatqueue %additem("ginseng", @eatqueue)}

You may also want to turn off the three alarms when you don't need them so that the command of the alarms are not executing every second. You may do this with a button, or better yet, with triggers that fire when you start a PK fight and when it ends.

Kjata

GURU Joined: 10 Oct 2000 Posts: 873 Location: USA

What are the alarms for? You should be able to save quite a bit of time by not using them. Just add something to the queue upon getting an affliction, and pop it off and do the healing action when you get the line telling you you can eat/drink another item. (or right upon getting the affliction if you're not waiting on being able to reheal)

(?)

Same script, just do the actions and updates in your "you may now eat another..." type triggers and in the affliction-receiving triggers you omitted.

I only see a use for the timers in order to be able to send out the "eat X" after the server sends "You are ready to..." but before it arrives at your computer. (a big deal for modem connections, because then you can make yourself competitive with the people who live next door to the server and have a cablemodem

To do that, trigger on "You eat whatever. You feel pretty good now!" and set an alarm for whatever the herb reuse time is. Send the next eat message by using the timer to guess when the "ready" message was sent (add a small margin to be safe). If you have a really slow ping time, take that into account in figuring out when the "You eat whatever!" was actually sent by the server.

-Tarn

Beginner Joined: 07 Dec 2001 Posts: 21

Some reason I can't get the following scripts to work..

#ALARM "eatalarm" {*1} {#IF ((@eat) and !(%item(@eatqueue, 1) != "")) {#VAR eat 0;eat %item(@eatqueue, 1);#VAR eatqueue %delitem(%item(@eatqueue, 1), @eatqueue)}}
#ALARM "drinkalarm" {*1} {#IF ((@drink) and !(%item(@drinkqueue, 1) != "")) {#VAR drink 0;drink %item(@drinkqueue, 1);#VAR drinkqueue %delitem(%item(@drinkqueue, 1), @drinkqueue)}}
#ALARM "applyalarm" {*1} {#IF ((@apply) and !(%item(@applyqueue, 1) != "")) {#VAR apply 0;apply %item(@applyqueue, 1);#VAR applyqueue %delitem(%item(@applyqueue, 1), @applyqueue)}}

I read over what Tarn suggested, but was a bit lost to about what he said...so thats not good either.

And there are also certain afflictions that needs to be cured first, before anything else can be cured. For instance, if I'm hit with anorexia, I can't eat or drink till thats cured. Is there a way to make it so these are cured first if I'm hit with them in the middle of battle?

GURU Joined: 10 Oct 2000 Posts: 4379 Location: USA

Your right, I initially used the alarms to put a counter so it would know when the three seconds were up, but then I used the line that says you may eat/drink/apply again and left the alarms there.

It's much better the way you said.

Kjata

Beginner Joined: 07 Dec 2001 Posts: 21

Hrm...about the best I can do is taking out the various herbs and vials and such...but it won't eat or drink! *Sigh* Sorry, just bear with me, I'm learning slowly, but learning.

Still havn't figured out how to priortize what should be eaten/drank/applied first though. Thats a bit out of my league

GURU Joined: 10 Oct 2000 Posts: 4379 Location: USA

Ok, here is the script like Tarn suggested:
#VAR eatqueue ""
#VAR applyqueue ""
#VAR drinkqueue ""
#VAR eat 1
#VAR apply 1
#VAR drink 1
#ALIAS eatq {#IF ((@eat) and (%item(@eatqueue, 1) = "")) {eat %1;#VAR eat 0} {#IF (%2 = 1) {#VAR eatqueue %concat(%1, "|", @eatqueue)} {#VAR eatqueue %additem(%1, @eatqueue)}}}
#ALIAS applyq {#IF ((@apply) and (%item(@applyqueue, 1) = "")) {apply %1;#VAR apply 0} {#IF (%2 = 1) {#VAR applyqueue %concat(%1, "|", @applyqueue)} {#VAR applyqueue %additem(%1, @applyqueue)}}}
#ALIAS drinkq {#IF ((@drink) and (%item(@drinkqueue, 1) = "")) {drink %1;#VAR drink 0} {#IF (%2 = 1) {#VAR drinkqueue %concat(%1, "|", @drinkqueue)} {#VAR drinkqueue %additem(%1, @drinkqueue)}}}
#TRIGGER {You may eat another plant.} {#IF (%item(@eatqueue, 1) = "") {#VAR eat 1} {eat %item(@eatqueue, 1);#VAR eatqueue %delitem(%item(@eatqueue, 1), @eatqueue)}}
#TRIGGER {You may apply another salve to yourself.} {#IF (%item(@applyqueue, 1) = "") {#VAR apply 1} {apply %item(@applyqueue, 1);#VAR applyqueue %delitem(%item(@applyqueue, 1), @applyqueue)}}
#TRIGGER {You may drink another affliction-healing elixir.} {#IF (%item(@drinkqueue, 1) = "") {#VAR drink 1} {drink %item(@drinkqueue, 1);#VAR drinkqueue %delitem(%item(@drinkqueue, 1), @drinkqueue)}}
#TRIGGER {You get anorexia.} {Outb anorexiacure;applyq "anorexiacure" 1}
#TRIGGER {You feel light headed and dizzy.} {Outb ginseng;eatq "ginseng"}
#TRIGGER {Your right arm breaks from all the damage.} {Outb mending;applyq "mending"}
#TRIGGER {You begin feeling slightly flushed.} {Outb immunity;drinkp "immunity"}

Ok, so here you go. You need to enter these commands, one by one in the command-line. They will create the necessary script to drive your affliction healing engine. After you have entered them, you need to create triggers for all of the possible afflictions that you can get. The basic syntax for the triggers will be:
#TRIGGER {Affliction message} {Outb HealingItem;[eatq/applyq/drinkq] "HealingItem" <Urgent>}

Where Affliction message is the line received from the MUD when you get this affliction, HealingItem is the item necessary to cure this affliction and Urgent is an optional argument that specifies that the item must be eaten/drank/applied before any others if it is 1.

The last for triggers were included as an example. The first one of these is for anorexia (since you didn't provde the message and item, I just made them up) and uses the optional Urgent argument of the applyq to cure it as soon as possible. The other three are taken form the examples you provided, one item needs to be eaten, the other applied and the last one drank.

The aliases just look at the queue and decide if they should eat/drink/apply the item right away or put in the queue list. If you are not waiting for the message that tells you that you may eat/drink/apply another item, and the queue list is empty, it will eat/drink/apply the item right away. If however, one of these two is not true, it adds it to the list so that you may cure it when you are ready to do it. If the optional Urgent aregument is present and it is 1, then the item is added to the beginning of the queue list (instead of the ened) so that it may be eaten/drank/applied on the next turn.

Kjata

Beginner Joined: 07 Dec 2001 Posts: 21

Thanks! It seems to be working out great, and pretty simple to understand. Two final questions though.

Firstly, is there a way to not have these triggers set off by someone simply saying the message?

Secondly, there are conditions like where I'm tied up and I have to writhe free before I can do any other action, is it possible for the triggers to be put on hold till I write free?

GURU Joined: 14 Oct 2000 Posts: 556 Location: USA

quote:

Firstly, is there a way to not have these triggers set off by someone simply saying the message?

Yes, anchor the trigger patterns with ^ and $. ^ anchors the pattern to a begining of line. $ anchors the pattern to end-of-line. So that if the pattern is:
^You may eat another plant.$
Then it will not match:
Joebob says, 'You may eat another plant.'
since this does not start on the beginning of line.

quote:

Secondly, there are conditions like where I'm tied up and I have to writhe free before I can do any other action, is it possible for the triggers to be put on hold till I write free?

You could stick everything in a class and turn the class on and off with triggers in response to your writhing.

Troubadour

GURU Joined: 10 Oct 2000 Posts: 873 Location: USA

Very nice, Kjata!

quote:

You could stick everything in a class and turn the class on and off with triggers in response to your writhing.

You only want to suspend actually eating/drinking. You can still receive afflictions while you have any of the conditions that prevent you from healing (being tied up, running about in panic, etc.) so you still want to be adding them to the queue.

I'd suggest adding a few aliases which are also tied to macro keys:
1) suspend eating/drinking in the queue (probably via setting a flag checked in the aliases that eat/drink)
2) resume healing from the queues (same variable, plus instantly try to heal from each queue depending on whether you're ready to or not)
2) clear the queues (empty the stringlist variables)
3) add specific items to the queues (aliases are already there for this)

Achaea is tricky, and while heavy automation can give a huge advantage, you have to be able to manually override everything in an emergency.

-Tarn

Posted: Sun Jan 13, 2002 11:49 am

Just thought I'd give you some details that might help...
herbs, salves and elixirs all have separate balances of 1 second each, except for restoration salve, which is 3 seconds.

A piece of advice --> no matter how good an automatic curing system you write, STILL make it highlight afflictions with colours the correspond to cures. That way you can keep track of how its going and step in to override it if needed.

Caled

Beginner Joined: 07 Dec 2001 Posts: 21

quote:

I'd suggest adding a few aliases which are also tied to macro keys:
1) suspend eating/drinking in the queue (probably via setting a flag checked in the aliases that eat/drink)
2) resume healing from the queues (same variable, plus instantly try to heal from each queue depending on whether you're ready to or not)
2) clear the queues (empty the stringlist variables)
3) add specific items to the queues (aliases are already there for this)

How exactly would I go about doing that? I'm just not entierly sure on the script.

GURU Joined: 10 Oct 2000 Posts: 873 Location: USA

quote:

How exactly would I go about doing that? I'm just not entierly sure on the script.

Ok, pretend I can count and actually numbered my suggestions properly

1) Right now, the variables EAT, APPLY, and DRINK determine whether you will do those things given the chance. How about another three variables, EATRUN, APPLYRUN, and DRINKRUN, that must be 1 in order to make the aliases like




#ALIAS eatq {#IF ((@eat) and (%item(@eatqueue, 1) = "")) {eat %1;#VAR eat 0} {#IF (%2 = 1) {#VAR eatqueue %concat(%1, "|", @eatqueue)} {#VAR eatqueue %additem(%1, @eatqueue)}}}

do their thing? Then, you can toggle these variables via an alias, trigger, or macro when one or more can't actually be done- asleep, stunned, anorexic, etc.

2) see (1)- this would be the alias/trigger/macro that turns those variables back on

3) set the stringlist variable equal to an empty string. #VAR eatqueue "" for instance.

4) An alias version of the triggers that add things to the lists:




#TRIGGER {You feel light headed and dizzy.} {Outb ginseng;eatq "ginseng"}

would also exist as an alias which does the same thing. (Or you can make the alias/macro do something like




#SHOW You feel light headed and dizzy.

and let the trigger go off.

How you want to do this would depend a little on what else you have set up already. Are you just getting started, or do you have a pretty good framework already?

For Caled's suggestion: By all means, highlight everything important. You might also look at some of the 'tell window' scripts in the forum to break really important stuff totally out of the battle spam.

-Tarn

Posted: Tue Jan 15, 2002 8:26 am

I've experimented with a lot of curing techniques for Achaea. At one stage I even had an completely automatic system that worked quite nicely, though I have since gone more manual because I felt like I was cheating, the other way. I'm not going to go giving any of my systems away, I'm sure you can understand that....but I'm willing to give hints.

Part of curing in Achaea is to get the order of curing correct. If you get two afflictions at one...anorexia and paralysis, for example - zmud needs to know to cure the anorexia before eating the bloodroot, otherwise you might as well not use triggers at all.

One way to do it is to make an alias to for every affliction. That alias should eat the relevant cure (or drink/apply).

001_stupidity
020_clumsiness

#additem herbaffs 001_stupidity
#additem herbaffs 020_clumsiness
%sort(@herbaffs)
#IF @herbb {%item(@herbaffs,1)}

Those are a few commands you might find useful.

One last hint - base the entire thing on one alias that has a whole lot of #IFs in it. You can use #ABORT 1 to stop the process if you're stunned etc, and you can make sure anorexia etc is cured before you start extracting other afflictions from the lists.

Oh yeah...and have separate lists for salves/herbs.

Caled

Posted: Tue Jan 15, 2002 8:29 am

Oh yeah...one last thing...to Tarn.

Zugg told me off while back for using the ['code]['/code] thing...it plays havoc with the word wrap and generally annoys people. *hint hint*

Caled

Beginner Joined: 07 Dec 2001 Posts: 21

Originally, I had it set up so it would Echo back what I needed to cure, "Eat Blah" "Apply Blah" and so on and I just did the cures myself. However I want to know just how much of a difference between that system and an automatic systems is first hand.

So far I have everything done according to what Kjata pointed out and that seems to be working just fine, till I get put to sleep, or something of the sort. I can easily shut off the class when something like that happens, but as pointed out earlier, I can still be hit with afflictions during those times where I cannot cure.

Other than that, its working quite well, though at times I'm better off curing manually, so I have to classess, one with the echos, and one that cures autmatically.

I understand what Tarn said to explain his points, but on how to actually do it? I havn't a clue.

Beginner Joined: 07 Dec 2001 Posts: 21

So umm...does anybody have any ideas of how to do what I wanted in the post prior to this one?

Beginner Joined: 25 Jan 2003 Posts: 14 Location: Australia

Hi,

I was just wondering whether anyone had gotten any further with this, by making it able to stop curing while you were restricted by sleep, paralsysis, etc but still able to add the cures to the list to be cured. I have searched using the search tool but haven't been able to come up with anything. Does anyone else have any ideas?

i know the posts aboce are old, but they are still relevant to Achaea. Or is there a better way of doing things now? with the never versions of Zmud?

any help would be appreciated,

-Dan

GURU Joined: 10 Oct 2000 Posts: 4379 Location: USA

To make it wait if you are sleeping you need to add another check to the #IF's in the applyq, drinkq, and eatq aliases. Right now it is like this:
((@eat) and (%item(@eatqueue, 1) = ""))

So, you should change it to this:
((!@sleep) and (@eat) and (%item(@eatqueue, 1) = ""))

The #IF's in the triggers that fire when you may eat/drink/apply again should also be modified to include a check for sleeping. So this:
(%item(@applyqueue, 1) = "")

should be:
((@sleep) or (%item(@applyqueue, 1) = ""))

Finally, you create triggers that will set the variable @sleep to 0 when you are sleeping and to 1 when you wake up. The trigger that sets the variable to 1 when you wake up should also display the message that you may eat/drink/apply another cure if that particular variable is 1, to set things in motion again. Example:
#TRIGGER {You wake up.} {#VAR sleep 0;#IF (@eat) {#SH You may eat another plant.};#IF (@drink) {#SH You may drink another affliction-healing elixir.};#IF (@apply) {#SH You may apply another salve to yourself.}}

Kjata

Newbie Joined: 23 Jan 2003 Posts: 3 Location: Sweden

Well, I'm experienced when it comes to Achaea systems, and my advice is to make the trigger for the affliction as such
(done in settings editor)
Trigger pattern: (paralysis syntax)
commands to execute on trigger:
#if (@herbbalance) {%additem("ebl",@herblist)} {ebl}
herbbalance=1

Now, ebl is an alias for
outb bloodroot
eat bloodroot
eat bloodroot
eat bloodroot

This might get a little spammy, but you have to take in mind if you have stupidity, which might make you do nothing, and if you have amnesia, which makes Achaea ignore the first command you send to achaea.

The BIG trigger will be the one for You may eat another plant. In there you will get a large #IF and in there you should put the various statements, like
#if (@sleep=0) {#IF (@anorexia=0) and so on for all the priority afflictions and if you pass all those, the regular %item and %delitem

Don't know if this will help ya, but that's a very simplified and brief explanation of how I put up my systems.

Don Coulane
"A Soldier of the Golden Apples Corps says, "Never attempt to distract a masturbating gorilla."

Beginner Joined: 25 Jan 2003 Posts: 14 Location: Australia

Kjata,

I have tried what you said, but what i'm getting is that i'm taking the herb out from my pack but not eating it. I may not have something set correctly.

GURU Joined: 10 Oct 2000 Posts: 4379 Location: USA

Please post the complete script that you have until now.

As it is, it should always take out herb/elixir/salve out of the pack when you are hit with the affliction, but it will not be used until you can eat/drink/apply another cure or until you are no longer asleep. Of course, all of these variables must be set correctly by their corresponding triggers.

Kjata

Beginner Joined: 25 Jan 2003 Posts: 14 Location: Australia

Hi,

Here's the complete script that i am using, i've put it into the format which you were using above. What i have done is created a whole new character without any of my usually triggers etc and have only this system loaded, that way i know that nothing else is interfeering with it. One question that i do have is what is the '!' mark used for in '!@sleep'? The script that i'm using is as follows:

#VAR eatqueue ""
#VAR applyqueue ""
#VAR drinkqueue ""
#VAR eat 1
#VAR apply 1
#VAR drink 1
#VAR sleep 1

#ALIAS eatq {#IF ((!sleep) and (@eat) and (%item(@eatqueue, 1) = "")) {eat %1;#VAR eat 0} {#IF (%2 = 1) {#VAR eatqueue

%concat(%1, "|", @eatqueue)} {#VAR eatqueue %additem(%1, @eatqueue)}}}

#ALIAS applyq {#IF ((!sleep) and (@apply) and (%item(@applyqueue, 1) = "")) {apply %1;#VAR apply 0} {#IF (%2 = 1) {#VAR

applyqueue %concat(%1, "|", @applyqueue)} {#VAR applyqueue %additem(%1, @applyqueue)}}}

#ALIAS drinkq {#IF ((!sleep) and (@drink) and (%item(@drinkqueue, 1) = "")) {drink %1;#VAR drink 0} {#IF (%2 = 1) {#VAR

drinkqueue %concat(%1, "|", @drinkqueue)} {#VAR drinkqueue %additem(%1, @drinkqueue)}}}

#TRIGGER {You may eat another plant.} {#IF ((@sleep) or (%item(@eatqueue, 1) = "")) {#VAR eat 1} {eat %item(@eatqueue,

1);#VAR eatqueue %delitem(%item(@eatqueue, 1), @eatqueue)}}

#TRIGGER {You may apply another salve to yourself.} {#IF ((@sleep) or (%item(@applyqueue, 1) = "")) {#VAR apply 1} {apply

%item(@applyqueue, 1);#VAR applyqueue %delitem(%item(@applyqueue, 1), @applyqueue)}}

#TRIGGER {You may drink another affliction-healing elixir.} {#IF ((@sleep) or (%item(@drinkqueue, 1) = "")) {#VAR drink 1}

{drink %item(@drinkqueue, 1);#VAR drinkqueue %delitem(%item(@drinkqueue, 1), @drinkqueue)}}

#TRIGGER {You wake up.} {#VAR sleep 0;#IF (@eat) {#SH You may eat another plant.};#IF (@drink) {#SH You may drink another affliction-healing elixir.};#IF (@apply) {#SH You may apply another salve to yourself.}}

A sample trigger would be

#TRIGGER {You feel light headed and dizzy.} {Outb ginseng;eatq "ginseng"}

Thanks alot for your help, it's really appreciated