 |
SethRizzen
Beginner
Joined: 07 Apr 2003
Posts: 15
Location: USA
|
 Posted: Thu Jul 22, 2004 12:20 am
Decent Spellup Script for Temporal Rifts MUD
|
Took me awhile to get this one working and could probably be improved upon. Any suggestions for improvement are greatly appreciated.
| Code: |
#CLASS 0
#ALIAS SpellUp {#if (@class == "witch") {#var SpellUp {"armor"|"shield"|"air armor"|"stone skin"|"infravision"|"bless"|"frenzy"|"pass door"|"farsight"|"invisibility"};#var SkillUp {"sneak"|"deft"}};#if (@class == "mage") {#var SpellUp {"armor"|"shield"|"air armor"|"stone skin"|"infravision"|"pass door"|"farsight"|"invisibility"};#var SkillUp {"deft"|"dash"}};#if (@race == "Hatchling") {#var RacialSpells {"scales"}};#T+ SpellUp;af}
#VAR SpellUp {}
#VAR SkillUp {}
#VAR RacialSpells {}
#CLASS {SpellUp}
#TRIGGER {^You are currently affected by the following flags~:} {#T- SpellUp;#while (@SpellUp <> "") {c '%pop( SpellUp)'};#while (@SkillUp <> "") {%pop( SkillUp)};#while (@RacialSpells <> "") {c '%pop( RacialSpells)'}}
#TRIGGER {^Spell~: (%1)(%s)~: modifies %2} {#if (%ismember( %1, @SpellUp)) {#var SpellUp %delitem( %1, @SpellUp)};#if (%ismember( %1, @SkillUp)) {#var SkillUp %delitem( %1, @SkillUp)};#if (%ismember( %1, @RacialSpells)) {#var RacialSpells %delitem( %1, @RacialSpells)}}
#CLASS 0
#CLASS {Score}
#TRIGGER {~|Race~: %1 (%s) ~Class~: %3 (%s) Gender~: %5 (%s) ~|} {#var race %1;#var class %3;#var gender %5}
#VAR race {Teen}
#VAR gender {Male}
#VAR class {mage}
#CLASS 0
|
The Score class is to update your race and class info for the script. This script assumes you know these spells and are of the appropriate level for them. Enjoy! |
|
Last edited by SethRizzen on Thu Jul 22, 2004 1:54 am; edited 1 time in total |
 |
|
|
SethRizzen
Beginner
Joined: 07 Apr 2003
Posts: 15
Location: USA
|
Posted: Thu Jul 22, 2004 1:46 am Improved SpellUp Script for Mages/Witches
|
To make this script portable between characters, I made it work for mages and witches. Soon to come is all classes! MMMMuuuuuuahahahaha.
| Code: |
#CLASS 0
#ALIAS {SpellUp} {
#var SpellUp ""
#var SkillUp ""
#var RacialSpells ""
#if (@class == "witch") {
#if (@level >= 6) {
#additem SpellUp "detect invis"
#additem SpellUp "detect good"
#additem SpellUp "detect evil"
#additem SpellUp "detect magic"
#additem SpellUp "invisibility"
}
#if (@level >= 12) {#additem SpellUp "farsight"}
#if (@level >= 15) {
#additem SpellUp "protection evil"
#additem SpellUp "protection good"
}
#if (@level >= 20) {#additem SpellUp "armor"}
#if (@level >= 26) {#additem SpellUp "shield"}
#if (@level >= 28) {#additem SpellUp "fly"}
#if (@level >= 31) {#additem SpellUp "stone skin"}
#if (@level >= 46) {#additem SpellUp "frenzy"}
#if (@level >= 50) {
#additem SpellUp "haste"
#additem SpellUp "sanctuary"
}
#if (@level >= 60) {#additem SpellUp "bless"}
#if (@level >= 79) {#additem SpellUp "druid call"}
#if (@level >= 190) {
#additem SpellUp "air armor"
#additem SpellUp "supernatural speed"
}
#if (@level >= 10) {#additem SkillUp "sneak"}
#if (@level >= 29) {#additem SkillUp "deft"}
}
#if (@class == "mage") {
#if (@level >= 2) {#additem SpellUp "detect magic"}
#if (@level >= 3) {#additem SpellUp "detect invis"}
#if (@level >= 5) {#additem SpellUp "invisibility"}
#if (@level >= 7) {#additem SpellUp "armor"}
#if (@level >= 10) {#additem SpellUp "fly"}
#if (@level >= 11) {
#additem SpellUp "detect evil"
#additem SpellUp "detect good"
}
#if (@level >=12) {
#additem SpellUp "protection good"
#additem SpellUp "protection evil"
}
#if (@level >= 14) {#additem SpellUp "farsight"}
#if (@level >= 20) {#additem SpellUp "shield"}
#if (@level >= 21) {#additem SpellUp "haste"}
#if (@level >= 25) {#additem SpellUp "stone skin"}
#if (@level >= 36) {#additem SpellUp "sanctuary"}
#if (@level >= 180) {#additem SpellUp "air armor"}
}
#if (@race == "Hatchling") {#if (@level >= 10) {#additem RacialSpells "scales"}}
#T+ SpellUp
af
}
#CLASS {SpellUp}
#TRIGGER {^~(%1hp %2m %3v~)%4} {
#T- SpellUp
#while (@SpellUp <> "") {c '%pop( SpellUp)'};
#while (@SkillUp <> "") {%pop( SkillUp)}
#while (@RacialSpells <> "") {c '%pop( RacialSpells)'}
} "" {prompt}
#TRIGGER {^Spell~: (%1)(%s)~: modifies %2} {
#if (%ismember( %1, @SpellUp)) {#var SpellUp %delitem( %1, @SpellUp)}
#if (%ismember( %1, @SkillUp)) {#var SkillUp %delitem( %1, @SkillUp)}
#if (%ismember( %1, @RacialSpells)) {#var RacialSpells %delitem( %1, @RacialSpells)}
}
#TRIGGER {invisible} {#delitem SpellUp "invisibility"}
#TRIGGER {detect_evil} {#delitem SpellUp "detect good"}
#TRIGGER {detect_invis} {#delitem SpellUp "detect invis"}
#TRIGGER {detect_magic} {#delitem SpellUp "detect magic"}
#TRIGGER {sanctuary} {#delitem SpellUp "sanctuary"}
#TRIGGER {druid_call} {#delitem SpellUp "druid call"}
#TRIGGER {infrared} {#delitem SpellUp "infravision"}
#TRIGGER {^Spell~: supernatural speed~: modifies none by 0 for %1 hours.} {#delitem SpellUp "supernatural speed"}
#TRIGGER {prot_evil} {#delitem SpellUp "protection evil"}
#TRIGGER {prot_good} {#delitem SpellUp "protection good"}
#TRIGGER {sneak} {#delitem SkillUp "sneak"}
#TRIGGER {flying} {#delitem SpellUp "fly"}
#TRIGGER {pass_door} {#delitem SpellUp "pass door"}
#TRIGGER {haste} {#delitem SpellUp "haste"}
#TRIGGER {air_armor} {#delitem SpellUp "air armor"}
#VAR SpellUp {}
#VAR SkillUp {}
#VAR RacialSpells {}
#CLASS 0
#CLASS {Score}
#VAR age {}
#VAR hours {}
#VAR race {}
#VAR gender {}
#VAR class {}
#VAR name {}
#VAR level {}
#TRIGGER {~|Name~: %1 (%s) Level~: %3 (%s) Age~: %5 ~(%6(%s)hours~)~ |} {
#var name %1
#var level %3
#var age %5
#var hours %6
}
#TRIGGER {~|Race~: %1 (%s) ~Class~: %3 (%s) Gender~: %5 (%s) ~|} {
#var race %1
#var class %3
#var gender %5
}
#CLASS 0 |
Again, the Score class is for updating your level and race. I suggest typing score before using the script. Enjoy! |
|
|
|
|
|
|
|
|
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
|
|
